diff --git a/gnome-extra/evolution-data-server/evolution-3.44.4-r1.ebuild b/gnome-extra/evolution-data-server/evolution-3.44.4-r1.ebuild
deleted file mode 100644
index d76bcab..0000000
--- a/gnome-extra/evolution-data-server/evolution-3.44.4-r1.ebuild
+++ /dev/null
@@ -1,153 +0,0 @@
-# Copyright 1999-2022 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-inherit cmake gnome2 readme.gentoo-r1
-
-DESCRIPTION="Integrated mail, addressbook and calendaring functionality"
-HOMEPAGE="https://wiki.gnome.org/Apps/Evolution https://gitlab.gnome.org/GNOME/evolution"
-
-# Note: explicitly "|| ( LGPL-2 LGPL-3 )", not "LGPL-2+".
-LICENSE="|| ( LGPL-2 LGPL-3 ) CC-BY-SA-3.0 FDL-1.3+ OPENLDAP"
-SLOT="2.0"
-
-IUSE="archive +bogofilter geolocation gtk-doc highlight ldap spamassassin spell ssl +weather ytnef phonenumber"
-
-KEYWORDS="amd64 ~arm arm64 ~ppc64 ~riscv x86"
-
-# glade-3 support is for maintainers only per configure.ac
-# pst is not mature enough and changes API/ABI frequently
-# dconf explicitely needed for backup plugin
-# gnome-desktop support is optional with --enable-gnome-desktop
-# automagic libunity dep
-# >=gspell-1.8 to ensure it uses enchant:2 like webkit-gtk
-DEPEND="
-	>=app-crypt/gcr-3.4:=[gtk]
-	>=app-text/enchant-2.2.0:2
-	>=dev-db/sqlite-3.7.17
-	>=dev-libs/glib-2.56:2[dbus]
-	>=dev-libs/libxml2-2.7.3:2
-	>=gnome-base/gnome-desktop-2.91.3:3=
-	>=gnome-base/gsettings-desktop-schemas-2.91.92
-	>=gnome-extra/evolution-data-server-${PV}:=[gtk,weather?]
-	>=media-libs/libcanberra-0.25[gtk3]
-	>=net-libs/libsoup-2.42:2.4
-	>=net-libs/webkit-gtk-2.28.0:4=[spell?]
-	>=x11-libs/cairo-1.9.15[glib]
-	>=x11-libs/gdk-pixbuf-2.24:2
-	>=x11-libs/gtk+-3.22:3
-	>=x11-libs/libnotify-0.7
-	>=x11-misc/shared-mime-info-0.22
-
-	app-text/cmark:=
-	>=app-text/iso-codes-0.49
-	dev-libs/atk
-	gnome-base/dconf
-	x11-libs/libSM
-	x11-libs/libICE
-
-	archive? ( >=app-arch/gnome-autoar-0.1.1[gtk] )
-	bogofilter? ( mail-filter/bogofilter )
-	geolocation? (
-		>=media-libs/libchamplain-0.12:0.12[gtk]
-		>=media-libs/clutter-1.0.0:1.0
-		>=media-libs/clutter-gtk-0.90:1.0
-		>=sci-geosciences/geocode-glib-3.10.0:0 )
-	ldap? ( >=net-nds/openldap-2:= )
-	spamassassin? ( mail-filter/spamassassin )
-	spell? ( >=app-text/gspell-1.8:= )
-	ssl? (
-		>=dev-libs/nspr-4.6.1
-		>=dev-libs/nss-3.11
-	)
-	weather? ( >=dev-libs/libgweather-3.91.0:4= )
-	ytnef? ( net-mail/ytnef )
-	phonenumber? (
-		>=dev-libs/libphonenumber-8.12.39
-	)
-"
-RDEPEND="${DEPEND}
-	highlight? ( app-text/highlight )
-"
-BDEPEND="
-	app-text/docbook-xml-dtd:4.1.2
-	dev-util/gdbus-codegen
-	dev-util/glib-utils
-	dev-util/itstool
-	gtk-doc? ( dev-util/gtk-doc
-		app-text/docbook-xml-dtd:4.3 )
-	>=dev-util/intltool-0.40.0
-	>=sys-devel/gettext-0.18.3
-	virtual/pkgconfig
-"
-
-DISABLE_AUTOFORMATTING="yes"
-DOC_CONTENTS="To change the default browser if you are not using GNOME, edit
-~/.local/share/applications/mimeapps.list so it includes the
-following content:
-
-[Default Applications]
-x-scheme-handler/http=firefox.desktop
-x-scheme-handler/https=firefox.desktop
-
-(replace firefox.desktop with the name of the appropriate .desktop
-file from /usr/share/applications if you use a different browser)."
-
-# global scope PATCHES or DOCS array mustn't be used due to double default_src_prepare
-# call; if needed, set them after cmake_src_prepare call, if that works
-
-src_prepare() {
-	cmake_src_prepare
-	gnome2_src_prepare
-}
-
-src_configure() {
-	# Use NSS/NSPR only if 'ssl' is enabled.
-	local mycmakeargs=(
-		-DSYSCONF_INSTALL_DIR="${EPREFIX}"/etc
-		-DENABLE_SCHEMAS_COMPILE=OFF
-		-DENABLE_GTK_DOC=$(usex gtk-doc)
-		-DWITH_OPENLDAP=$(usex ldap)
-		-DWITH_PHONENUMBER=$(usex phonenumber)
-		-DENABLE_SMIME=$(usex ssl)
-		-DENABLE_GNOME_DESKTOP=ON
-		-DWITH_ENCHANT_VERSION=2
-		-DENABLE_CANBERRA=ON
-		-DENABLE_AUTOAR=$(usex archive)
-		-DWITH_HELP=ON
-		-DENABLE_YTNEF=OFF
-		-DWITH_BOGOFILTER=$(usex bogofilter)
-		-DWITH_SPAMASSASSIN=$(usex spamassassin)
-		-DENABLE_GSPELL=$(usex spell)
-		-DENABLE_TEXT_HIGHLIGHT=$(usex highlight)
-		-DENABLE_WEATHER=$(usex weather)
-		-DWITH_GWEATHER4=ON
-		-DENABLE_CONTACT_MAPS=$(usex geolocation)
-		-DENABLE_YTNEF=$(usex ytnef)
-		-DENABLE_PST_IMPORT=OFF
-		-DWITH_GLADE_CATALOG=OFF
-		-DENABLE_MARKDOWN=ON
-	)
-
-	cmake_src_configure
-}
-
-src_compile() {
-	cmake_src_compile
-}
-
-src_test() {
-	cmake_src_test
-}
-
-src_install() {
-	cmake_src_install
-
-	readme.gentoo_create_doc
-}
-
-pkg_postinst() {
-	gnome2_pkg_postinst
-	readme.gentoo_print_elog
-}
diff --git a/gnome-extra/evolution-data-server/evolution-data-server-3.44.4.ebuild b/gnome-extra/evolution-data-server/evolution-data-server-3.44.4.ebuild
new file mode 100755
index 0000000..98466b7
--- /dev/null
+++ b/gnome-extra/evolution-data-server/evolution-data-server-3.44.4.ebuild
@@ -0,0 +1,158 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake db-use flag-o-matic gnome2 vala virtualx
+
+DESCRIPTION="Evolution groupware backend"
+HOMEPAGE="https://wiki.gnome.org/Apps/Evolution"
+
+# Note: explicitly "|| ( LGPL-2 LGPL-3 )", not "LGPL-2+".
+LICENSE="|| ( LGPL-2 LGPL-3 ) BSD Sleepycat"
+SLOT="0/63-26-20" # subslot = libcamel-1.2/libedataserver-1.2/libebook-1.2.so soname version
+
+IUSE="berkdb +gnome-online-accounts +gtk gtk-doc +introspection ipv6 ldap kerberos oauth vala +weather phonenumber"
+REQUIRED_USE="vala? ( introspection )"
+
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux ~x86-solaris"
+
+# gdata-0.17.7 soft required for new gdata_feed_get_next_page_token API to handle more than 100 google tasks
+# berkdb needed only for migrating old addressbook data from <3.13 versions, bug #519512
+# glib-2.70 for build-time optional GPowerProfileMonitor
+gdata_depend=">=dev-libs/libgdata-0.17.7:="
+RDEPEND="
+	>=app-crypt/gcr-3.4
+	>=app-crypt/libsecret-0.5[crypt]
+	>=dev-db/sqlite-3.7.17:=
+	>=dev-libs/glib-2.70:2
+	>=dev-libs/libical-3.0.8:=[glib,introspection?]
+	>=dev-libs/libxml2-2
+	>=dev-libs/nspr-4.4:=
+	>=dev-libs/nss-3.9:=
+	>=net-libs/libsoup-2.58:2.4
+
+	dev-libs/icu:=
+	sys-libs/zlib:=
+	virtual/libiconv
+
+	berkdb? ( >=sys-libs/db-4:= )
+	gtk? (
+		>=app-crypt/gcr-3.4[gtk]
+		>=x11-libs/gtk+-3.16:3
+		>=media-libs/libcanberra-0.25[gtk3]
+	)
+	oauth? (
+		>=dev-libs/json-glib-1.0.4
+		>=net-libs/webkit-gtk-2.28.0:4
+		${gdata_depend}
+	)
+	gnome-online-accounts? (
+		>=net-libs/gnome-online-accounts-3.8:=
+		${gdata_depend} )
+	introspection? ( >=dev-libs/gobject-introspection-0.9.12:= )
+	kerberos? ( virtual/krb5:= )
+	ldap? ( >=net-nds/openldap-2:= )
+	weather? ( >=dev-libs/libgweather-3.91.0:4= )
+	phonenumber? (
+		>=dev-libs/libphonenumber-8.12.39
+	)
+"
+DEPEND="${RDEPEND}
+	vala? ( $(vala_depend)
+		net-libs/libsoup:2.4[vala]
+		dev-libs/libical[vala]
+		oauth? ( dev-libs/libgdata[vala] )
+		gnome-online-accounts? ( dev-libs/libgdata[vala] )
+	)
+"
+BDEPEND="
+	dev-util/gdbus-codegen
+	dev-util/glib-utils
+	dev-util/gperf
+	gtk-doc? ( >=dev-util/gtk-doc-1.14
+		app-text/docbook-xml-dtd:4.1.2 )
+	>=dev-util/intltool-0.35.5
+	>=sys-devel/gettext-0.18.3
+	virtual/pkgconfig
+"
+
+# Some tests fail due to missing locales.
+# Also, dbus tests are flaky, bugs #397975 #501834
+# It looks like a nightmare to disable those for now.
+RESTRICT="test !test? ( test )"
+
+# global scope PATCHES or DOCS array mustn't be used due to double default_src_prepare call
+src_prepare() {
+	use vala && vala_setup
+	cmake_src_prepare
+	gnome2_src_prepare
+
+	eapply "${FILESDIR}"/3.36.5-gtk-doc-1.32-compat.patch
+
+	# Make CMakeLists versioned vala enabled
+	sed -e "s;\(find_program(VALAC\) valac);\1 ${VALAC});" \
+		-e "s;\(find_program(VAPIGEN\) vapigen);\1 ${VAPIGEN});" \
+		-i "${S}"/CMakeLists.txt || die
+}
+
+src_configure() {
+	# /usr/include/db.h is always db-1 on FreeBSD
+	# so include the right dir in CPPFLAGS
+	use berkdb && append-cppflags "-I$(db_includedir)"
+
+	local google_enable
+	if use oauth || use gnome-online-accounts; then
+		google_enable="ON"
+	else
+		google_enable="OFF"
+	fi
+
+	# phonenumber does not exist in tree
+	local mycmakeargs=(
+		-DSYSCONF_INSTALL_DIR="${EPREFIX}"/etc
+		-DENABLE_GTK_DOC=$(usex gtk-doc)
+		-DWITH_PRIVATE_DOCS=$(usex gtk-doc)
+		-DENABLE_SCHEMAS_COMPILE=OFF
+		-DENABLE_INTROSPECTION=$(usex introspection)
+		-DWITH_KRB5=$(usex kerberos)
+		-DWITH_KRB5_INCLUDES=$(usex kerberos "${EPREFIX}"/usr "")
+		-DWITH_KRB5_LIBS=$(usex kerberos "${EPREFIX}"/usr/$(get_libdir) "")
+		-DWITH_OPENLDAP=$(usex ldap)
+		-DWITH_PHONENUMBER=$(usex phonenumber)
+		-DENABLE_SMIME=ON
+		-DENABLE_GTK=$(usex gtk)
+		-DENABLE_CANBERRA=$(usex gtk)
+		-DENABLE_OAUTH2=$(usex oauth)
+		-DENABLE_EXAMPLES=OFF
+		-DENABLE_GOA=$(usex gnome-online-accounts)
+		-DWITH_LIBDB=$(usex berkdb "${EPREFIX}"/usr OFF)
+		# ENABLE_BACKTRACES requires libdwarf ?
+		-DENABLE_IPV6=$(usex ipv6)
+		-DENABLE_WEATHER=$(usex weather)
+		-DWITH_GWEATHER4=ON
+		-DENABLE_GOOGLE=${google_enable}
+		-DENABLE_LARGEFILE=ON
+		-DENABLE_VALA_BINDINGS=$(usex vala)
+	)
+
+	cmake_src_configure
+}
+
+src_compile() {
+	cmake_src_compile
+}
+
+src_test() {
+	virtx cmake_src_test
+}
+
+src_install() {
+	cmake_src_install
+
+	if use ldap; then
+		insinto /etc/openldap/schema
+		doins "${FILESDIR}"/calentry.schema
+		dosym ../../../usr/share/${PN}/evolutionperson.schema /etc/openldap/schema/evolutionperson.schema
+	fi
+}