diff --git a/net-im/dino/Manifest b/net-im/dino/Manifest
new file mode 100644
index 0000000..1cdd3c5
--- /dev/null
+++ b/net-im/dino/Manifest
@@ -0,0 +1 @@
+DIST dino-0.4.0.tar.gz 882288 BLAKE2B 7d05f358746c09d5c129db1366fdb609f796cdc11c889bc22f9d0d71daa1b9b622b83512e15cbfe8d1e6f3fcf2870f20d7e0c5ecbf66257e7a155d2e020f7652 SHA512 09abfda34625a680dd7bc4cfa842c6bcbc4097fa613bf91bb7c6a4a10d2075f5050d3be705379fd7ecf9c686024000cd6791757eb8b0958ff8e533774267085a
diff --git a/net-im/dino/dino-0.4.0.ebuild b/net-im/dino/dino-0.4.0.ebuild
new file mode 100644
index 0000000..07d394f
--- /dev/null
+++ b/net-im/dino/dino-0.4.0.ebuild
@@ -0,0 +1,87 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake vala xdg readme.gentoo-r1
+
+DESCRIPTION="Modern Jabber/XMPP Client using GTK+/Vala"
+HOMEPAGE="https://dino.im"
+
+LICENSE="GPL-3"
+SLOT="0"
+IUSE="+gpg +http +omemo +notification-sound test"
+RESTRICT="!test? ( test )"
+
+MY_REPO_URI="https://github.com/dino/dino"
+KEYWORDS="~amd64 ~arm64"
+SRC_URI="${MY_REPO_URI}/releases/download/v${PV}/${P}.tar.gz"
+
+
+RDEPEND="
+	app-text/gspell[vala]
+	dev-db/sqlite:3
+	dev-libs/glib:2
+	dev-libs/icu
+	dev-libs/libgee:0.8
+	net-libs/glib-networking
+	>=net-libs/libnice-0.1.15
+	net-libs/libsignal-protocol-c
+	net-libs/libsrtp:2
+	x11-libs/cairo
+	x11-libs/gdk-pixbuf:2
+	x11-libs/gtk+:3
+	x11-libs/pango
+	>=gui-libs/libadwaita-1.2.0
+	gpg? ( app-crypt/gpgme:= )
+	http? ( net-libs/libsoup:2.4 )
+	omemo? (
+		dev-libs/libgcrypt:0
+		media-gfx/qrencode
+	)
+	notification-sound? ( media-libs/libcanberra:0[sound] )
+"
+DEPEND="
+	${RDEPEND}
+	media-libs/gst-plugins-base
+	media-libs/gstreamer
+"
+BDEPEND="
+	sys-devel/gettext
+	$(vala_depend)
+"
+
+src_configure() {
+	vala_setup
+
+	local disabled_plugins=(
+		$(usex gpg "" "openpgp")
+		$(usex omemo "" "omemo")
+		$(usex http  "" "http-files")
+	)
+	local enabled_plugins=(
+		$(usex notification-sound "notification-sound" "")
+	)
+	local mycmakeargs+=(
+		"-DENABLED_PLUGINS=$(local IFS=";"; echo "${enabled_plugins[*]}")"
+		"-DDISABLED_PLUGINS=$(local IFS=";"; echo "${disabled_plugins[*]}")"
+		"-DVALA_EXECUTABLE=${VALAC}"
+		"-DBUILD_TESTS=$(usex test)"
+	)
+
+	cmake_src_configure
+}
+
+src_test() {
+	"${BUILD_DIR}"/xmpp-vala-test || die
+}
+
+src_install() {
+	cmake_src_install
+	readme.gentoo_create_doc
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	readme.gentoo_print_elog
+}
diff --git a/net-im/dino/files/README.gentoo b/net-im/dino/files/README.gentoo
new file mode 100644
index 0000000..b51e439
--- /dev/null
+++ b/net-im/dino/files/README.gentoo
@@ -0,0 +1,23 @@
+To enable video calls, install the following packages.
+
+Transport level security:
+- gst-plugins-srtp
+- gst-plugins-dtls
+
+Peer to peer connection reliability:
+- gst-plugins-libnice
+
+Video output into a window:
+- gst-plugins-gtk
+
+At least one codec is needed in common with the other end of the call, as they
+are negotiated when the call begins.
+
+Video codecs:
+- gst-plugins-x264
+- gst-plugins-vpx
+
+Audio codecs:
+- gst-plugins-good
+- gst-plugins-speex
+- gst-plugins-opus