diff --git a/net-im/dino-libhandy/Manifest b/net-im/dino-libhandy/Manifest
index ecb67be..9e42310 100644
--- a/net-im/dino-libhandy/Manifest
+++ b/net-im/dino-libhandy/Manifest
@@ -1 +1,2 @@
 DIST dino-libhandy-0.2.2.tar.gz 739269 BLAKE2B 890c4d3dfee899f570893ca788302312d160ed5af8f87350a8a9809791c7e948d495026ab01e5471179200e98b0ab6b4002e8cdbe1be07e3c6d43ddc85e37012 SHA512 1157c2221b0b127b151b79d6a5b1dd0a4141b9022cd148e2e347be026af950744d8a1030bb02ff27c3410653e3f18b30a5d2659fe2b24620e64004e95343e31d
+DIST dino-libhandy-0.3.1.tar.gz 845089 BLAKE2B 9801986ca173fbb468eb0f222a25ede86c3ead345f215be136819412691712c45d056f92a00150a7210558cfd504dba0fced621aa1104dc27487c805837ea3c5 SHA512 55cafa368401ad5b12b52014894e200c66d174430aaf264ef0dadef7b069ed9fb3d8de6d85a40579225744ba9ed938f58f0aaf314c950d88e5e7b04178a7a2e8
diff --git a/net-im/dino-libhandy/dino-libhandy-0.3.1.ebuild b/net-im/dino-libhandy/dino-libhandy-0.3.1.ebuild
new file mode 100644
index 0000000..f9ba4de
--- /dev/null
+++ b/net-im/dino-libhandy/dino-libhandy-0.3.1.ebuild
@@ -0,0 +1,86 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake vala xdg readme.gentoo-r1
+
+DESCRIPTION="Modern Jabber/XMPP Client using GTK+/Vala"
+HOMEPAGE="https://dino.im"
+
+LICENSE="GPL-3"
+SLOT="0"
+IUSE="+gpg +http +omemo +notification-sound test"
+RESTRICT="!test? ( test )"
+
+KEYWORDS="~amd64 ~arm64"
+
+COMMIT="e35df88d4a00c3a34f2b4d9fb7f10bb5d877bd29"
+SRC_URI="https://github.com/dino/dino/archive/${COMMIT}.tar.gz -> ${P}.tar.gz"
+
+RDEPEND="
+	app-text/gspell[vala]
+	dev-db/sqlite:3
+	dev-libs/glib:2
+	dev-libs/icu
+	dev-libs/libgee:0.8
+	net-libs/glib-networking
+	>=net-libs/libnice-0.1.15
+	net-libs/libsignal-protocol-c
+	net-libs/libsrtp:2
+	x11-libs/cairo
+	x11-libs/gdk-pixbuf:2
+	x11-libs/gtk+:3
+	x11-libs/pango
+	gpg? ( app-crypt/gpgme:= )
+	http? ( net-libs/libsoup:2.4 )
+	omemo? (
+		dev-libs/libgcrypt:0
+		media-gfx/qrencode
+	)
+	notification-sound? ( media-libs/libcanberra:0[sound] )
+"
+DEPEND="
+	${RDEPEND}
+	media-libs/gst-plugins-base
+	media-libs/gstreamer
+"
+BDEPEND="
+	sys-devel/gettext
+	$(vala_depend)
+"
+
+src_configure() {
+	vala_setup
+
+	local disabled_plugins=(
+		$(usex gpg "" "openpgp")
+		$(usex omemo "" "omemo")
+		$(usex http  "" "http-files")
+	)
+	local enabled_plugins=(
+		$(usex notification-sound "notification-sound" "")
+	)
+	local mycmakeargs+=(
+		"-DENABLED_PLUGINS=$(local IFS=";"; echo "${enabled_plugins[*]}")"
+		"-DDISABLED_PLUGINS=$(local IFS=";"; echo "${disabled_plugins[*]}")"
+		"-DVALA_EXECUTABLE=${VALAC}"
+		"-DBUILD_TESTS=$(usex test)"
+	)
+
+	cmake_src_configure
+}
+
+src_test() {
+	"${BUILD_DIR}"/xmpp-vala-test || die
+}
+
+src_install() {
+	cmake_src_install
+	readme.gentoo_create_doc
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	readme.gentoo_print_elog
+}