diff --git a/net-fs/s3fs/Manifest b/net-fs/s3fs/Manifest
new file mode 100644
index 0000000..3d9e249
--- /dev/null
+++ b/net-fs/s3fs/Manifest
@@ -0,0 +1 @@
+DIST s3fs-1.93.tar.gz 284353 BLAKE2B bae0d850f69f04b18327790406260721a0a2d981f5b2cbc8e6ebc059f4db83bd0810780b68d334a50cbba4654301a395683a778567ce3f08d4b9f69fef5ed282 SHA512 613ad713ac426236b471aa4b2f8292ee0558017f149bfe51aa7fad1bacd60fccf00c31404ebc14b692787e524704e9cd9111b84540f1309ba99900d42d03dc5d
diff --git a/net-fs/s3fs/s3fs-1.93.ebuild b/net-fs/s3fs/s3fs-1.93.ebuild
new file mode 100644
index 0000000..e45695a
--- /dev/null
+++ b/net-fs/s3fs/s3fs-1.93.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools
+
+MY_PN=${PN}-fuse
+MY_P=${MY_PN}-${PV}
+
+DESCRIPTION="Amazon S3 mounting via fuse"
+HOMEPAGE="https://github.com/s3fs-fuse/s3fs-fuse/"
+SRC_URI="https://github.com/${MY_PN}/${MY_PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~riscv ~x86 ~arm ~arm64"
+IUSE="gnutls nettle nss"
+REQUIRED_USE="nettle? ( gnutls !nss )"
+
+# Requires active internet connection and it tries to download some binaries for later execution
+RESTRICT="test"
+
+DEPEND="
+	dev-libs/libxml2:2
+	net-misc/curl
+	sys-fs/fuse:0
+	nss? ( dev-libs/nss )
+	!nss? (
+		gnutls? (
+			net-libs/gnutls:=
+			nettle? ( dev-libs/nettle:= )
+		)
+		!gnutls? ( dev-libs/openssl:0= )
+	)
+"
+
+RDEPEND="${DEPEND}
+	app-misc/mime-types
+"
+
+BDEPEND="virtual/pkgconfig"
+
+S="${WORKDIR}/${MY_P}"
+
+src_prepare() {
+	default
+
+	sed -i 's/-D_FORTIFY_SOURCE=2//' configure.ac || die
+
+	eautoreconf
+}
+
+src_configure() {
+	local myeconfargs=(
+		$(use_with nettle)
+	)
+	if use nss; then
+		myeconfargs+=( $(use_with nss) )
+	elif use gnutls; then
+		myeconfargs+=( $(use_with gnutls) )
+	else
+		myeconfargs+=( --with-openssl )
+	fi
+
+	econf "${myeconfargs[@]}"
+}