From 47779a13230ca43d8b5887d4325763a4ea22695c Mon Sep 17 00:00:00 2001
From: Gerben Jan Dijkman <gjdijkman@outlook.com>
Date: Fri, 16 Apr 2021 19:49:33 +0200
Subject: [PATCH] Added

---
 app-misc/gnote/Manifest          |  1 +
 app-misc/gnote/gnote-40.0.ebuild | 70 ++++++++++++++++++++++++++++++++
 2 files changed, 71 insertions(+)
 create mode 100644 app-misc/gnote/Manifest
 create mode 100644 app-misc/gnote/gnote-40.0.ebuild

diff --git a/app-misc/gnote/Manifest b/app-misc/gnote/Manifest
new file mode 100644
index 0000000..bd1c16e
--- /dev/null
+++ b/app-misc/gnote/Manifest
@@ -0,0 +1 @@
+DIST gnote-40.0.tar.xz 3418516 BLAKE2B 93834a3d9cdae89604be01b96c5293741263a1812ed23cc51a151c250f42c33c560456ac78a5a97f713dffc095b6f53ffe465da89867df89497239443939f3c4 SHA512 098273ee2de15152e7da739b857a8f7c43561e51013d1f42a631b0a9f52edebcd089817a9009556697e4c4b43506834919cd0f8cae7b3d899517f4b6d42eeb31
diff --git a/app-misc/gnote/gnote-40.0.ebuild b/app-misc/gnote/gnote-40.0.ebuild
new file mode 100644
index 0000000..0f0b64b
--- /dev/null
+++ b/app-misc/gnote/gnote-40.0.ebuild
@@ -0,0 +1,70 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit gnome2 readme.gentoo-r1
+
+DESCRIPTION="Desktop note-taking application"
+HOMEPAGE="https://wiki.gnome.org/Apps/Gnote"
+
+LICENSE="GPL-3+ FDL-1.1"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~arm ~arm64"
+IUSE="debug"
+
+# Automagic:
+# glib-2.32 dep
+# >=dev-libs/unittest++-1.5.1 (but not detected due to missing .pc)
+DEPEND="
+	>=app-crypt/libsecret-0.8
+	>=app-text/gspell-1.6.0:=
+	>=dev-cpp/glibmm-2.62.0:2
+	>=dev-cpp/gtkmm-3.22.20:3.0
+	>=dev-libs/glib-2.32:2[dbus]
+	>=dev-libs/libxml2-2:2
+	dev-libs/libxslt
+	>=sys-apps/util-linux-2.16:=
+	>=x11-libs/gtk+-3.22.20:3
+"
+RDEPEND="${DEPEND}
+	gnome-base/gsettings-desktop-schemas
+"
+BDEPEND="
+	app-text/docbook-xml-dtd:4.1.2
+	>=dev-util/intltool-0.35.0
+	dev-util/itstool
+	virtual/pkgconfig
+"
+
+src_prepare() {
+	# Do not alter CFLAGS
+	sed 's/-DDEBUG -g/-DDEBUG/' -i configure.ac configure || die
+
+	gnome2_src_prepare
+
+	if has_version net-fs/wdfs; then
+		DOC_CONTENTS="You have net-fs/wdfs installed. app-misc/gnote will use it to
+		synchronize notes."
+	else
+		DOC_CONTENTS="Gnote can use net-fs/wdfs to synchronize notes.
+		If you want to use that functionality just emerge net-fs/wdfs.
+		Gnote will automatically detect that you did and let you use it."
+	fi
+}
+
+src_configure() {
+	gnome2_src_configure \
+		--disable-static \
+		$(use_enable debug)
+}
+
+src_install() {
+	gnome2_src_install
+	readme.gentoo_create_doc
+}
+
+pkg_postinst() {
+	gnome2_pkg_postinst
+	readme.gentoo_print_elog
+}