Verion Bump

net-im/cawbird/cawbird-1.5-r2.ebuild

@@ -0,0 +1,77 @@
+# Copyright 2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit gnome2-utils meson vala xdg
+
+DESCRIPTION="Twitter client"
+HOMEPAGE="https://ibboard.co.uk/cawbird/ https://github.com/IBBoard/cawbird"
+SRC_URI="https://github.com/IBBoard/cawbird/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}"/${P}
+
+LICENSE="CC-BY-3.0 GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64"
+IUSE="gstreamer spell"
+
+RDEPEND="
+	dev-db/sqlite:3
+	dev-libs/atk
+	dev-libs/glib:2
+	dev-libs/json-glib
+	net-libs/liboauth
+	net-libs/libsoup:2.4
+	net-libs/rest:0.7
+	x11-libs/cairo
+	x11-libs/gdk-pixbuf:2
+	x11-libs/gtk+:3
+	x11-libs/libX11
+	x11-libs/pango
+	gstreamer? (
+		media-plugins/gst-plugins-gtk
+		media-plugins/gst-plugins-hls
+		media-plugins/gst-plugins-meta[ffmpeg,http,X]
+	)
+	spell? ( app-text/gspell:=[vala] )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	$(vala_depend)
+	virtual/pkgconfig
+"
+
+src_prepare() {
+	default
+
+	# Remove tests that require the network.
+	for test in avatardownload filters inlinemediadownloader \
+							   texttransform tweetparsing; do
+		sed -i "/${test}/d" tests/meson.build || die
+	done
+
+	vala_setup
+}
+
+src_configure() {
+	local emesonargs=(
+		# these keys are taken from the readme of cawbird
+		-Dconsumer_key_base64='VmY5dG9yRFcyWk93MzJEZmhVdEk5Y3NMOA=='
+		-Dconsumer_secret_base64='MThCRXIxbWRESDQ2Y0podzVtVU13SGUyVGlCRXhPb3BFRHhGYlB6ZkpybG5GdXZaSjI='
+		-Dexamples=false
+		$(meson_use spell spellcheck)
+		$(meson_use gstreamer video)
+		-Dx11=true
+	)
+	meson_src_configure
+}
+
+pkg_postinst() {
+	gnome2_schemas_update
+	xdg_pkg_postinst
+}
+
+pkg_postrm() {
+	gnome2_schemas_update
+	xdg_pkg_postrm
+}

net-im/cawbird/cawbird-1.5.ebuild

@@ -1,60 +0,0 @@
-# Copyright 1999-2021 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-VALA_USE_DEPEND="vapigen"
-
-inherit vala meson gnome2-utils xdg
-
-DESCRIPTION="Cawbird is a fork of the Corebird Twitter client from Baedert."
-HOMEPAGE="https://github.com/IBBoard/cawbird"
-SRC_URI="https://github.com/IBBoard/cawbird/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
-
-LICENSE="GPL-3"
-SLOT="0"
-KEYWORDS="~amd64 ~arm ~arm64 ~x86"
-IUSE="+introspection +vala"
-REQUIRED_USE="vala? ( introspection )"
-
-DEPEND="
-	gui-libs/gtk
-	>=x11-libs/gtk+-3.22
-	>=dev-libs/glib-2.44
-	>=dev-libs/json-glib-1.0
-	>=dev-db/sqlite-3.0
-	>=net-libs/libsoup-2.4:*
-	net-libs/liboauth
-	>=sys-devel/gettext-0.19
-	media-libs/gst-plugins-base
-	media-libs/gst-plugins-bad
-	media-plugins/gst-plugins-libav
-	>=app-text/gspell-1.0
-"
-RDEPEND="${DEPEND}"
-BDEPEND="
-		vala? ( $(vala_depend) )
-		dev-util/meson
-		dev-libs/gobject-introspection
-"
-src_prepare() {
-	eapply_user
-	vala_src_prepare
-}
-
-S="${WORKDIR}/$PN-${PV}"
-
-src_configure() {
-	local mycmakeargs+=(
-		"-DVALA_EXECUTABLE=${VALAC}"
-	)
-	
-	local emesonargs=(
-		-Dconsumer_key_base64=VmY5dG9yRFcyWk93MzJEZmhVdEk5Y3NMOA==
-		-Dconsumer_secret_base64=MThCRXIxbWRESDQ2Y0podzVtVU13SGUyVGlCRXhPb3BFRHhGYlB6ZkpybG5GdXZaSjI=
-	)
-	meson_src_configure
-}
-
-src_install() {
-	meson_src_install
-}