Version bump

dev-util/blueprint-compiler/Manifest

@@ -1 +1,2 @@
 DIST blueprint-compiler-v0.6.0.tar.bz2 56896 BLAKE2B 318ffa52b2fbf3b07058e5b4d2f9bb0ef1f6614586b79968889921964b454e5c26d44e58a18185263797f7569135662d14471bafd8e501d7c6386e88972193d0 SHA512 458016f4eabef15026cb3ee675111984b19af8a9139bc412dfb48dfef56b0d0ff028316001d0ce04a90b50d6785c92d799f17ed42ca53fc7582345729ae02207
+DIST blueprint-compiler-v0.8.1.tar.bz2 80762 BLAKE2B 9acd4a8e2e5d993a94bcf2c80530553a8f6c8977ebe94274e6a208935f6ddaf21dd1946ab80e08b4e61e16a8ff892301d9f9cf82f7af6e8d53c3b2fce3996592 SHA512 94a4651a54d69df1bcfa3e7219cefb2eca187808d0c2a580c135583fa0e2848a011a72204a567c48fce20a246d41667f7cbf147a34980b34c0914b4fc5868efb

dev-util/blueprint-compiler/blueprint-compiler-0.8.1.ebuild

@@ -0,0 +1,72 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..11} )
+
+inherit meson python-single-r1 virtualx
+
+DESCRIPTION="Compiler for Blueprint, a markup language for GTK user interfaces"
+HOMEPAGE="https://jwestman.pages.gitlab.gnome.org/blueprint-compiler/
+	https://gitlab.gnome.org/jwestman/blueprint-compiler/"
+
+if [[ ${PV} == *9999 ]] ; then
+	inherit git-r3
+	EGIT_REPO_URI="https://gitlab.gnome.org/jwestman/${PN}.git"
+else
+	SRC_URI="https://gitlab.gnome.org/jwestman/${PN}/-/archive/v${PV}/${PN}-v${PV}.tar.bz2"
+	S="${WORKDIR}"/${PN}-v${PV}
+	KEYWORDS="~amd64 ~x86 ~arm ~arm64"
+fi
+
+LICENSE="LGPL-3+"
+SLOT="0"
+IUSE="doc test"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	${PYTHON_DEPS}
+	$(python_gen_cond_dep '
+		dev-python/pygobject:3[${PYTHON_USEDEP}]
+	')
+"
+BDEPEND="
+	${RDEPEND}
+	doc? (
+		$(python_gen_cond_dep '
+			dev-python/furo[${PYTHON_USEDEP}]
+			dev-python/sphinx[${PYTHON_USEDEP}]
+		')
+	)
+	test? (
+		gui-libs/gtk:4[introspection]
+		gui-libs/libadwaita:1[introspection]
+	)
+"
+
+DOCS=( CONTRIBUTING.md MAINTENANCE.md NEWS.md README.md )
+
+src_configure() {
+	local -a emesonargs=(
+		$(meson_use doc docs)
+	)
+	meson_src_configure
+}
+
+src_compile() {
+	meson_src_compile
+
+	use doc && build_sphinx docs
+}
+
+src_test() {
+	virtx meson_src_test
+}
+
+src_install() {
+	meson_src_install
+	python_fix_shebang "${ED}"/usr/bin
+	python_optimize
+}