From 53803bc17b3e6d749483ba0be3e14d8bf9304bcd Mon Sep 17 00:00:00 2001
From: Gerben Jan Dijkman <gjdijkman@outlook.com>
Date: Wed, 3 Mar 2021 13:02:26 +0100
Subject: [PATCH] Added omemo support

---
 x11-plugins/lurch/Manifest           |  1 +
 x11-plugins/lurch/lurch-0.7.0.ebuild | 52 ++++++++++++++++++++++++++++
 2 files changed, 53 insertions(+)
 create mode 100644 x11-plugins/lurch/Manifest
 create mode 100644 x11-plugins/lurch/lurch-0.7.0.ebuild

diff --git a/x11-plugins/lurch/Manifest b/x11-plugins/lurch/Manifest
new file mode 100644
index 0000000..f30fea3
--- /dev/null
+++ b/x11-plugins/lurch/Manifest
@@ -0,0 +1 @@
+DIST lurch-0.7.0.tar.gz 66885 BLAKE2B 1a3cc1dbfd8f999b677b23d02952a3c28c922d438cfe81a3bfd3a03cc49723fcc4d52a549bfc7ecb45616a0c939b0f78a39f73a4439bc5337d4da656e9d42b11 SHA512 082f85d25fbcb184b7b6d827e1e6bac073ad46064a144ca24245164558ca9e0cdfcdc4187ac3da5f8738e0476e759e67801d0fd24598b31e2d86053f8af576b6
diff --git a/x11-plugins/lurch/lurch-0.7.0.ebuild b/x11-plugins/lurch/lurch-0.7.0.ebuild
new file mode 100644
index 0000000..69acd90
--- /dev/null
+++ b/x11-plugins/lurch/lurch-0.7.0.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit toolchain-funcs
+
+DESCRIPTION="OMEMO encryption for libpurple (XEP-0384)"
+HOMEPAGE="https://github.com/gkdr/lurch"
+SRC_URI="https://github.com/gkdr/lurch/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3"  # likely not GPL-3+, https://github.com/gkdr/lurch/issues/165
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~arm ~arm64"
+IUSE="test"
+
+# NOTE: Some of these dependencies seem like leftovers in the build system
+#       and can probably be dropped with lurch >=0.7.1
+#       (https://github.com/gkdr/lurch/issues/164)
+RDEPEND="
+	dev-db/sqlite
+	dev-libs/glib
+	dev-libs/libgcrypt:=
+	dev-libs/libxml2
+	dev-libs/mxml
+	net-im/pidgin:=
+	net-libs/libaxc
+	net-libs/libomemo
+	>=net-libs/libsignal-protocol-c-2.3.2
+	"
+DEPEND="
+	${RDEPEND}
+	virtual/pkgconfig
+	test? ( dev-util/cmocka )
+	"
+
+RESTRICT="!test? ( test )"
+
+src_prepare() {
+	rm -Rv lib/{axc,libomemo} || die  # unbundle
+	default
+}
+
+src_compile() {
+	local makeargs=(
+		CC="$(tc-getCC)"
+		LIBGCRYPT_CONFIG="$(tc-getPROG LIBGCRYPT_CONFIG libgcrypt-config)"
+		PKG_CONFIG="$(tc-getPKG_CONFIG)"
+		XML2_CONFIG="$(tc-getPROG XML2_CONFIG xml2-config)"
+	)
+	emake "${makeargs[@]}"
+}