Version bump

net-voip/gnome-calls/Manifest

@@ -1,2 +1,3 @@
-DIST calls-v48.2.tar.bz2 487553 BLAKE2B d797adaa00685e58e6a8b0b51dcf1614a284c3b209251331764b465a1e8a4b6a2d048b9599d2d7335f6f109e5296109173d14ca622eeb95da73d3e02201d7902 SHA512 16ac409baa9304a37c09aea5612f1919faacdb2eec5eb93e9eb4890cbfbac675b24059090424ea3a790c208532aa01b9e751016191b4abf1082df3b248bed4ac
+DIST calls-v49.1.1.tar.bz2 497917 BLAKE2B 92e7ba4b652447264687f19c1b151988deba95c62d533425f1da197407bb2a031511de0db81d8023c2eb8dc70ba046fb4473c5d1faaf6d5bba4510d226306f3f SHA512 95ee48cfc1ec4e37d14be2b0debb85cc86d8e0100a43665110c457ef1192270ae316ab20bafab082ce208763c3bdbe675f6cb5f55b66bb1f1cd370825f997b59
-DIST libcall-ui-v0.1.0.tar.bz2 161130 BLAKE2B 9c684802f1a17630bad25eacfb960522eee7b1a668239a9e2b4711dee24c26ae6926674742828f95072e26c7d0cc19fe704107c22cd5824734548189761aa9f8 SHA512 b2f29e48003d22ffb9d5392af35f6a3e6c5aa5aebb155dcd8cc890111b98f163ce3b7d843a6b5e8adf96272544c999b9e0fd7bfd358847dc87b38d0c942038c4
+DIST calls-v50.0.tar.bz2 512272 BLAKE2B c21babe74149c6e4b968eede26e5d1302cf3d97a094abb9da20b3d6c3dc3e83aa615bbca01a70109cd283937c0f7ee2108526fcf965ea2142f5ebba80846bc2f SHA512 7dc3ae4d69d83cf284e6e64a8f07e62c074e740f6efded4ecbfa20c8eb9f563619c6aded155f8cdb993d897123bee7f8f5fd3c7c1e085d554c41c4b53734955f
+DIST libcall-ui-v0.1.5.tar.bz2 167740 BLAKE2B cfbe1edc6375fb722f05d8e6a90ac8f61447113417e18bb88f90484b261d2f27981c138e292e7c07ce36eb22c5fa412fe8c2b5dead1185fe22690d8f0ae9a2fb SHA512 bdda14cb8200cca7b41145c022409a91287b1c9f83a7675126862bb348759bc9a0ffd2af95008fbb7724d256eb7d3ca7b796d70084c062c5ebbd57642d7db668

net-voip/gnome-calls/gnome-calls-49.1.1.ebuild

@@ -8,7 +8,7 @@ inherit vala meson gnome2-utils optfeature virtualx xdg
 
 MY_PN="${PN#gnome-}"
 MY_P="${MY_PN}-v${PV}"
-LCU_V="0.1.0"
+LCU_V="0.1.5"
 DESCRIPTION="Phone dialer and call handler"
 HOMEPAGE="https://gitlab.gnome.org/GNOME/calls"
 GITLAB="https://gitlab.gnome.org"

net-voip/gnome-calls/gnome-calls-50.0.ebuild

@@ -0,0 +1,114 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+VALA_USE_DEPEND="vapigen"
+
+inherit vala meson gnome2-utils optfeature virtualx xdg
+
+MY_PN="${PN#gnome-}"
+MY_P="${MY_PN}-v${PV}"
+LCU_V="0.1.5"
+DESCRIPTION="Phone dialer and call handler"
+HOMEPAGE="https://gitlab.gnome.org/GNOME/calls"
+GITLAB="https://gitlab.gnome.org"
+SRC_URI="
+	${GITLAB}/GNOME/${MY_PN}/-/archive/v${PV}/${MY_P}.tar.bz2
+	${GITLAB}/World/Phosh/libcall-ui/-/archive/v${LCU_V}/libcall-ui-v${LCU_V}.tar.bz2
+"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="CC0-1.0 CC-BY-SA-4.0 GPL-3+ LGPL-2+ LGPL-2.1+"
+SLOT="0"
+#KEYWORDS="~amd64 ~arm64"
+IUSE="gtk-doc man"
+
+RDEPEND="
+	app-crypt/libsecret[introspection,vala]
+	dev-libs/feedbackd[introspection,vala]
+	dev-libs/folks:=
+	dev-libs/glib:2
+	dev-libs/gom[introspection]
+	dev-libs/libgee:0.8=[introspection]
+	>=dev-libs/libpeas-2.0.0
+	gnome-extra/evolution-data-server:=[vala]
+	gui-libs/libhandy:1[introspection,vala]
+	media-libs/gstreamer:1.0[introspection]
+	media-sound/callaudiod
+	net-libs/sofia-sip
+	net-misc/modemmanager:=[introspection]
+	x11-libs/gtk+:3
+"
+DEPEND="${RDEPEND}
+	test? ( media-plugins/gst-plugins-srtp:1.0 )
+"
+BDEPEND="
+	$(vala_depend)
+	dev-libs/gobject-introspection
+	dev-libs/protobuf
+	dev-util/wayland-scanner
+	gtk-doc? ( dev-util/gtk-doc )
+	man? ( dev-python/docutils )
+"
+
+src_unpack() {
+	default
+
+	cd "${S}" || die
+	rmdir subprojects/libcall-ui || die
+	mv "${WORKDIR}"/libcall-ui-v${LCU_V} subprojects/libcall-ui || die
+}
+
+src_prepare() {
+	default
+	vala_setup
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use gtk-doc gtk_doc)
+		$(meson_use man manpages)
+		$(meson_use test tests)
+	)
+	meson_src_configure
+}
+
+src_test() {
+	local tests=(
+		calls:call
+		calls:contacts
+		calls:dbus
+		calls:manager
+		calls:media
+		calls:origin
+		calls:plugins
+		calls:provider
+		calls:sdp-crypto
+		calls:settings
+		calls:srtp
+		calls:ui-call
+		calls:util
+
+		# TODO: needs working sound card
+		#calls:application
+
+		# TODO: failure related to feedbackd
+		#calls:ringer
+
+		# TODO: hangs
+		#calls:sip
+	)
+	virtx meson_src_test "${tests[@]}"
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+
+	optfeature "SRTP support" media-plugins/gst-plugins-srtp
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}