From 634049bb38ef28746c304b37af178a2e271670a1 Mon Sep 17 00:00:00 2001
From: Gerben Jan Dijkman <gjdijkman@outlook.com>
Date: Mon, 1 Mar 2021 16:53:36 +0100
Subject: [PATCH] Added gnome music

---
 media-sound/gnome-music/Manifest              |  1 +
 .../gnome-music/gnome-music-3.38.2-r1.ebuild  | 82 +++++++++++++++++++
 2 files changed, 83 insertions(+)
 create mode 100644 media-sound/gnome-music/Manifest
 create mode 100644 media-sound/gnome-music/gnome-music-3.38.2-r1.ebuild

diff --git a/media-sound/gnome-music/Manifest b/media-sound/gnome-music/Manifest
new file mode 100644
index 0000000..bf856d1
--- /dev/null
+++ b/media-sound/gnome-music/Manifest
@@ -0,0 +1 @@
+DIST gnome-music-3.38.2.tar.xz 974312 BLAKE2B 2fc2b47bb19a05e4c1c17142fa534fbd8b08661fd1a9845610f03eb3dbe9e9784ee339b39b3cb82b476dfddec0726f531c8a9fd0b52e108a598a5f81245b0c90 SHA512 c80b06798da7da159faba7ea44239444a72ea58af350ee8e82a90f7cff45efe9c6b7663e4fb36db1dafc2241fa738fffc49d488b6773eb4c431f4c502742b35f
diff --git a/media-sound/gnome-music/gnome-music-3.38.2-r1.ebuild b/media-sound/gnome-music/gnome-music-3.38.2-r1.ebuild
new file mode 100644
index 0000000..7cf4b3c
--- /dev/null
+++ b/media-sound/gnome-music/gnome-music-3.38.2-r1.ebuild
@@ -0,0 +1,82 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{6,7,8} )
+
+inherit gnome.org gnome2-utils meson python-single-r1 xdg
+
+DESCRIPTION="Music management for Gnome"
+HOMEPAGE="https://wiki.gnome.org/Apps/Music"
+
+LICENSE="GPL-2+"
+SLOT="0"
+IUSE=""
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+KEYWORDS="~amd64 ~arm64 ~x86"
+
+DEPEND="${PYTHON_DEPS}
+	>=dev-libs/glib-2.50:2
+	>=net-libs/gnome-online-accounts-3.35.90[introspection]
+	>=dev-libs/gobject-introspection-1.54:=
+	>=x11-libs/gtk+-3.24.7:3[introspection]
+	>=x11-libs/pango-1.44
+	>=dev-libs/libdazzle-3.28.0[introspection]
+	>=media-libs/libmediaart-1.9.1:2.0[introspection]
+	net-libs/libsoup:2.4[introspection]
+	>=app-misc/tracker-3.0:=[introspection(+)]
+	$(python_gen_cond_dep '
+		>=dev-python/pygobject-3.29.1:3[cairo,${PYTHON_MULTI_USEDEP}]
+		>=dev-python/pycairo-1.14.0[${PYTHON_MULTI_USEDEP}]
+	')
+	>=media-libs/grilo-0.3.12:0.3[introspection]
+	>=media-plugins/grilo-plugins-0.3.10:0.3
+"
+# xdg-user-dirs-update needs to be there to create needed dirs
+# https://bugzilla.gnome.org/show_bug.cgi?id=731613
+RDEPEND="${DEPEND}
+	|| (
+		>=app-misc/tracker-miners-3.0[gstreamer]
+		>=app-misc/tracker-miners-3.0[ffmpeg]
+	)
+	x11-libs/libnotify[introspection]
+	media-libs/gstreamer:1.0[introspection]
+	media-libs/gst-plugins-base:1.0[introspection]
+	media-plugins/gst-plugins-meta:1.0
+	>=media-plugins/grilo-plugins-0.3.12-r1
+	x11-misc/xdg-user-dirs
+"
+BDEPEND="
+	dev-libs/libxml2:2
+	dev-util/itstool
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+"
+
+RESTRICT="test" # only does desktop and appdata validation, and latter needs network to validate screenshot from https
+
+pkg_setup() {
+	python_setup
+}
+
+src_prepare() {
+	sed -e '/sys.path.insert/d' -i "${S}"/gnome-music.in || die "python fixup sed failed"
+	xdg_src_prepare
+}
+
+src_install() {
+	meson_src_install
+	python_fix_shebang "${D}"/usr/bin/gnome-music
+	python_optimize
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}