diff --git a/dev-libs/wayland/Manifest b/dev-libs/wayland/Manifest
new file mode 100644
index 0000000..c5622c6
--- /dev/null
+++ b/dev-libs/wayland/Manifest
@@ -0,0 +1 @@
+DIST wayland-1.19.0.tar.xz 456380 BLAKE2B 0f70bb02e890898c4763001884527067adb686abe9a2b9325badf1730d411d269c437037afc298eec8075eb1e3845f5b81b8ed3d702908388a54e7063cbea91a SHA512 d8a86f5e23e4a88e7c84b82fdb51eb350419086afe462ecb2f4d5c3ba9290ede310cbbcffd60215219ddccf5bad4adec21a5ebfbef6577200f66ac7a1b64a5ef
diff --git a/dev-libs/wayland/wayland-1.19.0.ebuild b/dev-libs/wayland/wayland-1.19.0.ebuild
new file mode 100644
index 0000000..058e90a
--- /dev/null
+++ b/dev-libs/wayland/wayland-1.19.0.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+if [[ ${PV} = *9999* ]]; then
+	EGIT_REPO_URI="https://gitlab.freedesktop.org/wayland/wayland.git"
+	inherit git-r3
+else
+	SRC_URI="https://wayland.freedesktop.org/releases/${P}.tar.xz"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+fi
+inherit meson-multilib
+
+DESCRIPTION="Wayland protocol libraries"
+HOMEPAGE="https://wayland.freedesktop.org/ https://gitlab.freedesktop.org/wayland/wayland"
+
+LICENSE="MIT"
+SLOT="0"
+IUSE="doc"
+
+BDEPEND="
+	~dev-util/wayland-scanner-${PV}[$MULTILIB_USEDEP]
+	virtual/pkgconfig
+	doc? (
+		>=app-doc/doxygen-1.6[dot]
+		app-text/xmlto
+		>=media-gfx/graphviz-2.26.0
+	)
+"
+DEPEND="
+	>=dev-libs/expat-2.1.0-r3:=[${MULTILIB_USEDEP}]
+	dev-libs/libxml2:=
+	>=dev-libs/libffi-3.0.13-r1:=[${MULTILIB_USEDEP}]
+"
+RDEPEND="${DEPEND}"
+
+multilib_src_configure() {
+	local emesonargs=(
+		$(meson_native_use_bool doc documentation)
+		$(meson_native_true dtd_validation)
+		-Dlibraries=true
+		-Dscanner=false
+	)
+	meson_src_configure
+}
+
+src_test() {
+	# We set it on purpose to only a short subdir name, as socket paths are
+	# created in there, which are 108 byte limited. With this it hopefully
+	# barely fits to the limit with /var/tmp/portage/${CATEGORY}/${PF}/temp/x
+	export XDG_RUNTIME_DIR="${T}"/x
+	mkdir "${XDG_RUNTIME_DIR}" || die
+	chmod 0700 "${XDG_RUNTIME_DIR}" || die
+
+	multilib-minimal_src_test
+}