From 6c723a7b37916085718970caef2fec4debc98928 Mon Sep 17 00:00:00 2001
From: Gerben Jan Dijkman <gjdijkman@outlook.com>
Date: Sat, 29 May 2021 13:17:58 +0200
Subject: [PATCH] Version Bump

---
 net-misc/owncloud-client/Manifest             |  1 +
 .../owncloud-client-2.8.2.4246.ebuild         | 84 +++++++++++++++++++
 2 files changed, 85 insertions(+)
 create mode 100644 net-misc/owncloud-client/owncloud-client-2.8.2.4246.ebuild

diff --git a/net-misc/owncloud-client/Manifest b/net-misc/owncloud-client/Manifest
index 4ad9672..a76962a 100644
--- a/net-misc/owncloud-client/Manifest
+++ b/net-misc/owncloud-client/Manifest
@@ -1,2 +1,3 @@
 DIST ownCloud-2.7.6.3261.tar.xz 14237692 BLAKE2B 914b069b10fa2f169677768e1578c5b8569836eb574889c72c0ea1ca3e16e6b7c65bcdd1f4a5ce4259eab6ec56110e3b45799d010921e47c7f64ccfd0ed545bf SHA512 1f647dd0b33472e31719651fa22b5864867d98fa1e2f11f9eadb6ce15382f5f97ac49d726af079716b6fac573367485a6f11a5b2e5e5c95d4d063f6caab51dcd
 DIST ownCloud-2.8.1.4157.tar.xz 15033724 BLAKE2B 591945117988dc2e86885ef97c8743d6696173178da3997ac9eb3eb3c712f4e3e4d60d95dd31926ae6b02b9d5939984430a558a0bb6045d9c929f20ee70fc090 SHA512 99444f5531a8c7b2796bcf72be8d0eb12f11859262c29a0a177b3679334d91ee14e4a1725a91486640ea75bef95075fe9941ff25dfb4d731e4529f27b48c3228
+DIST ownCloud-2.8.2.4246.tar.xz 15044652 BLAKE2B ee1ee412667266273a9a9722940559562c6c43213b013fe7c21328e04ac967afb16f460e6fa711f37d1d4ea7d0fc15fc398d835cf6a939f4c8dfd54cd4846fed SHA512 0ab2ef72191cc2d5c2621c97c09cb1d25472a30f511235a190465e246a8312f13a255011abb9690c481887f2f15094414c87ce594252eb8debcb39b9cbc8a178
diff --git a/net-misc/owncloud-client/owncloud-client-2.8.2.4246.ebuild b/net-misc/owncloud-client/owncloud-client-2.8.2.4246.ebuild
new file mode 100644
index 0000000..fde2399
--- /dev/null
+++ b/net-misc/owncloud-client/owncloud-client-2.8.2.4246.ebuild
@@ -0,0 +1,84 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake xdg
+
+MY_PN="ownCloud"
+DESCRIPTION="Synchronize files from ownCloud Server with your computer"
+HOMEPAGE="https://owncloud.org/"
+SRC_URI="https://download.owncloud.com/desktop/${MY_PN}/stable/${PV}/source/${MY_PN}-${PV}.tar.xz"
+
+LICENSE="CC-BY-3.0 GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~arm64"
+IUSE="doc dolphin gnome-keyring nautilus test"
+
+COMMON_DEPEND=">=dev-db/sqlite-3.4:3
+	dev-libs/qtkeychain[gnome-keyring?,qt5(+)]
+	dev-qt/qtconcurrent:5
+	dev-qt/qtcore:5
+	dev-qt/qtdbus:5
+	dev-qt/qtgui:5
+	dev-qt/qtnetwork:5[ssl]
+	dev-qt/qtsql:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtxml:5
+	sys-fs/inotify-tools
+	dolphin? (
+		kde-frameworks/kcoreaddons:5
+		kde-frameworks/kio:5
+	)
+	nautilus? ( dev-python/nautilus-python )"
+
+RDEPEND="${COMMON_DEPEND}"
+DEPEND="${COMMON_DEPEND}
+	dev-qt/linguist-tools:5
+	kde-frameworks/extra-cmake-modules
+	doc? (
+		dev-python/sphinx
+		dev-tex/latexmk
+		dev-texlive/texlive-latexextra
+		virtual/latex-base
+	)
+	test? (
+		dev-util/cmocka
+		dev-qt/qttest:5
+	)"
+
+RESTRICT="!test? ( test )"
+
+S=${WORKDIR}/${MY_PN}-${PV}
+
+src_prepare() {
+	# Keep tests in ${T}
+	sed -i -e "s#\"/tmp#\"${T}#g" test/test*.cpp || die
+
+	if ! use nautilus; then
+		pushd shell_integration > /dev/null || die
+		cmake_comment_add_subdirectory nautilus
+		popd > /dev/null || die
+	fi
+	cmake_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DSYSCONF_INSTALL_DIR="${EPREFIX}"/etc
+		-DCMAKE_INSTALL_DOCDIR=/usr/share/doc/${PF}
+		-DCMAKE_DISABLE_FIND_PACKAGE_Sphinx=$(usex !doc)
+		-DBUILD_SHELL_INTEGRATION_DOLPHIN=$(usex dolphin)
+		-DBUILD_TESTING=$(usex test)
+	)
+
+	cmake_src_configure
+}
+
+pkg_postinst() {
+	if ! use doc ; then
+		elog "Documentation and man pages not installed"
+		elog "Enable doc USE-flag to generate them"
+	fi
+	xdg_pkg_postinst
+}