diff --git a/net-libs/libqmi/Manifest b/net-libs/libqmi/Manifest
new file mode 100644
index 0000000..a47aef2
--- /dev/null
+++ b/net-libs/libqmi/Manifest
@@ -0,0 +1 @@
+DIST libqmi-1.28.2.tar.xz 1165204 BLAKE2B 17f7462d84b74099a5ef4fa6f28e777a4587be0a7652b38c4ab5c0f50bbbbd0b8b293df22d7a8c470444df23fd405e3b176e8c449019787c5305fef13d0b27b2 SHA512 10d11b780aa381e93669aad2540c609bcd3f789302ed76d80b9845a24f84d8741b8c39287a2007ec80d8e0e517686023d08a7a677426c77f3b12ec172edc05e7
diff --git a/net-libs/libqmi/libqmi-1.28.2.ebuild b/net-libs/libqmi/libqmi-1.28.2.ebuild
new file mode 100644
index 0000000..51ac033
--- /dev/null
+++ b/net-libs/libqmi/libqmi-1.28.2.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit multilib
+if [[ ${PV} == "9999" ]] ; then
+	inherit git-r3 autotools
+	EGIT_REPO_URI="https://gitlab.freedesktop.org/mobile-broadband/libqmi.git"
+else
+	KEYWORDS="~amd64 ~arm ~arm64 ~mips ~ppc ~ppc64 ~x86"
+	SRC_URI="https://www.freedesktop.org/software/libqmi/${P}.tar.xz"
+fi
+
+DESCRIPTION="Qualcomm MSM (Mobile Station Modem) Interface (QMI) modem protocol library"
+HOMEPAGE="https://www.freedesktop.org/wiki/Software/libqmi/ https://gitlab.freedesktop.org/mobile-broadband/libqmi"
+
+LICENSE="LGPL-2"
+SLOT="0/5.7"	# soname of libqmi-glib.so
+IUSE="doc +mbim"
+
+RDEPEND=">=dev-libs/glib-2.48
+	dev-libs/libgudev
+	mbim? ( >=net-libs/libmbim-1.18.0 )"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	virtual/pkgconfig
+	doc? ( dev-util/gtk-doc )"
+[[ ${PV} == "9999" ]] && BDEPEND+=" dev-util/gtk-doc" #469214
+
+src_prepare() {
+	default
+	[[ ${PV} == "9999" ]] && eautoreconf
+}
+
+src_configure() {
+	econf \
+		--disable-Werror \
+		--disable-static \
+		$(use_enable mbim mbim-qmux) \
+		$(use_enable {,gtk-}doc)
+}
+
+src_install() {
+	default
+	find "${ED}" -name '*.la' -delete || die
+}