diff --git a/net-libs/sofia-sip/Manifest b/net-libs/sofia-sip/Manifest
index d22ac53..22bdde3 100644
--- a/net-libs/sofia-sip/Manifest
+++ b/net-libs/sofia-sip/Manifest
@@ -1 +1,2 @@
 DIST sofia-sip-1.13.18.tar.gz 2560124 BLAKE2B 241a544fe2156b56ea23c2b3b2856e9bf08571868c71cb0ff5adc951be5ff6533a09791bfc7882711822ab878b2a9a7fef8baa6f0af88b704cc552dd2340baa7 SHA512 e8c674b37be08abecc5d1dd5e0df0c25a35ff89ac4bd652215f5c5b0fdeecc83d1a2ed5ecc558466854b7cdb9c6d5573804aef85fae780d03f78d8ea9f714241
+DIST sofia-sip-1.13.19.tar.gz 2560113 BLAKE2B 1b9a7ab9178cbbdce0d066358c86f0b6a03492f470e3204626ef2b5a069fe569e6d81a65d55e874c7374f6e93e33dda45567fb58ce33fbf8e07ee8fd8e843f7f SHA512 ec9135aaa133009d1dc0db9780ce3202124e2f9cbcb1e5e1b440c81907556e0512623bdc61e851c9c01d007901ae4fd5cba9405529cce3011de309daa1f82ca5
diff --git a/net-libs/sofia-sip/sofia-sip-1.13.19.ebuild b/net-libs/sofia-sip/sofia-sip-1.13.19.ebuild
new file mode 100644
index 0000000..d0bcba4
--- /dev/null
+++ b/net-libs/sofia-sip/sofia-sip-1.13.19.ebuild
@@ -0,0 +1,114 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools
+
+DESCRIPTION="RFC3261 compliant SIP User-Agent library"
+HOMEPAGE="https://github.com/freeswitch/sofia-sip"
+SRC_URI="https://github.com/freeswitch/${PN}/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="LGPL-2.1+ BSD public-domain" # See COPYRIGHT
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-linux"
+IUSE="debug doc +glib test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-libs/openssl:=
+	sys-libs/zlib:=
+	glib? ( dev-libs/glib:2 )
+"
+DEPEND="${RDEPEND}
+	test? ( dev-libs/check )
+"
+BDEPEND="
+	virtual/pkgconfig
+	doc? ( app-text/doxygen[dot] )
+"
+
+DOCS=(
+	AUTHORS
+	ChangeLog{,.ext-trees}
+	README{,.developers}
+	RELEASE
+	SECURITY.md
+	TODO
+	docs/.
+)
+
+src_prepare() {
+	local -a TESTS_DESELECT=(
+		# Avoid tests that make too many assumptions about the
+		# networking environment, bug 915904
+		libsofia-sip-ua/sresolv:run_test_sresolv
+		libsofia-sip-ua/nta:run_test_nta
+		libsofia-sip-ua/nta:run_check_nta
+		libsofia-sip-ua/nua:check_nua
+		libsofia-sip-ua-glib/su-glib:torture_su_glib_timer
+		libsofia-sip-ua-glib/su-glib:su_source_test
+		tests:check_sofia
+		tests:test_nua
+	)
+
+	local testname filename
+	for deselect in "${TESTS_DESELECT[@]}"; do
+		filename="${deselect%%:*}/Makefile.am"
+		testname=${deselect#*:}
+		sed -i -e "/TESTS/,$ s/\<${testname:?}\>//" "${filename:?}" || die
+	done
+
+	default
+	eautoreconf
+}
+
+src_configure() {
+	local myeconfargs=(
+		# Makes otherwise working tests fail.
+		ac_cv_tagstack=no
+
+		# 'nth' depends on openssl (bug 851546, 880451) and can't be flipped off
+		# without breaking API and ABI, so it should always be enabled.
+		--enable-nth
+		--with-openssl
+
+		# ABI-breaking, cannot be controlled via USE-flags
+		--disable-experimental
+		--disable-sctp
+
+		$(use_enable !debug ndebug)
+		$(use_with doc doxygen)
+		$(use_with glib)
+	)
+	econf "${myeconfargs[@]}"
+
+	SOFIA_MAKEARGS=(
+		# Make build logs verbose
+		SOFIA_SILENT=
+		VERBOSE=1
+		# Prevent "/bin/sh /bin/sh" (bug 920903)
+		TESTS_ENVIRONMENT=
+	)
+}
+
+src_compile() {
+	emake "${SOFIA_MAKEARGS[@]}"
+
+	if use doc; then
+		emake -C libsofia-sip-ua "${SOFIA_MAKEARGS[@]}" doxygen
+		HTML_DOCS=( libsofia-sip-ua/docs/html/. )
+	fi
+}
+
+src_test() {
+	local -x SOFIA_DEBUG=9
+	emake "${SOFIA_MAKEARGS[@]}" check
+}
+
+src_install() {
+	emake DESTDIR="${D}" "${SOFIA_MAKEARGS[@]}" install
+	einstalldocs
+
+	find "${ED}" -name '*.la' -delete || die
+}