diff --git a/net-libs/libomemo/Manifest b/net-libs/libomemo/Manifest
new file mode 100644
index 0000000..910b73b
--- /dev/null
+++ b/net-libs/libomemo/Manifest
@@ -0,0 +1 @@
+DIST libomemo-0.7.1.tar.gz 23770 BLAKE2B a3909650e399075f62026bd048a667a276a6cd7197ac18ddf9e3c12f57e5fd9cb2f5532ba69d0836af87e1415a5ffdc1746cf90a596dcf255265a64e921f039d SHA512 e5769dee4db7be246853e47e29ded9eefad2f62422951ce5dd0c1acee3bb92131c0423f09bc716be0f55fb02c747f07a6d5b2c656bdfeee0ee148252c51a1050
diff --git a/net-libs/libomemo/libomemo-0.7.1-r2.ebuild b/net-libs/libomemo/libomemo-0.7.1-r2.ebuild
new file mode 100644
index 0000000..7ca3cbb
--- /dev/null
+++ b/net-libs/libomemo/libomemo-0.7.1-r2.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DESCRIPTION="Implementation of OMEMO (XEP-0384) in C"
+HOMEPAGE="https://github.com/gkdr/libomemo"
+SRC_URI="https://github.com/gkdr/libomemo/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~arm64 ~arm"
+IUSE="static-libs test"
+
+RDEPEND="
+	dev-db/sqlite
+	dev-libs/glib
+	dev-libs/libgcrypt
+	dev-libs/mxml
+	"
+DEPEND="
+	${RDEPEND}
+	virtual/pkgconfig
+	test? ( dev-util/cmocka )
+	"
+
+RESTRICT="!test? ( test )"
+
+PATCHES=(
+	"${FILESDIR}"/${P}-so-symlinks.patch
+)
+
+DOCS=( CHANGELOG.md README.md )
+
+src_compile() {
+	emake PREFIX=/usr
+}
+
+src_install() {
+	emake DESTDIR="${D}" PREFIX=/usr install
+
+	# Respect libdir other than /usr/lib, e.g. /usr/lib64
+	local libdir="$(get_libdir)"
+	if [[ ${libdir} != lib ]]; then
+		mv "${D}"/usr/{lib,${libdir}} || die
+		sed "s|^libdir=.*|libdir=\${prefix}/${libdir}|" \
+				-i "${D}/usr/${libdir}/pkgconfig/libomemo.pc" || die
+	fi
+
+	einstalldocs
+
+	if ! use static-libs ; then
+		rm "${D}/usr/${libdir}/libomemo.a" || die
+	fi
+}