Version bump

net-voip/gnome-calls/Manifest

@@ -1,3 +1,3 @@
-DIST calls-v45.0.tar.bz2 468539 BLAKE2B e696d91570e65eb3ba6884c760e76be4b6a15bbbb84f0c577fcd55be7168d2e0cce2ecd5825b0e106d56cd060118335019a7549e85fd6a5c3ea563677abdcb25 SHA512 6d7987b024e0b674122ea9693a921ff6505710812e06121ff102bf110648a402e5ab33915618ee96593ae429a13653e5ac8bcf30e528f5fc873c20167a61f818
 DIST calls-v46.3.tar.bz2 481214 BLAKE2B 3e4b7edf3f50fd4355cbb828967280de53735b1577f726c097870b4d84f05b2af13ba27e821dc0ab2408629882dc1c062673b17c2682ea9af904c0bd445067ff SHA512 4816e0fee3fb1dc097a440858f36dd777efc41d7eea0178db08fbcc662d266be20a1b3b70937dbca81bb1f16997728a048f4725c31b753dca5c7a072f608e06d
+DIST calls-v47.0.tar.bz2 478275 BLAKE2B d0c842ea8b3ea2ca0fde33ccb06bc99d4d6c8f82b470f535f11f4e1cd540f2d1a9369e52744937ac259d9b45ace32b5a827796254001bb67d9d1348dc3c57156 SHA512 1a137e4afbd71bd7ba80b9a3054f5f2032ba14b5cd451752c8ac58955c7ee32ed1c23cf24bce53653a93c091ac90071630fdce8838dfbf9d45d3f9f51c64c9b4
 DIST libcall-ui-v0.1.0.tar.bz2 161130 BLAKE2B 9c684802f1a17630bad25eacfb960522eee7b1a668239a9e2b4711dee24c26ae6926674742828f95072e26c7d0cc19fe704107c22cd5824734548189761aa9f8 SHA512 b2f29e48003d22ffb9d5392af35f6a3e6c5aa5aebb155dcd8cc890111b98f163ce3b7d843a6b5e8adf96272544c999b9e0fd7bfd358847dc87b38d0c942038c4

net-voip/gnome-calls/gnome-calls-47.0.ebuild

@@ -0,0 +1,114 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+VALA_USE_DEPEND="vapigen"
+
+inherit vala meson gnome2-utils optfeature virtualx xdg
+
+MY_PN="${PN#gnome-}"
+MY_P="${MY_PN}-v${PV}"
+LCU_V="0.1.0"
+DESCRIPTION="Phone dialer and call handler"
+HOMEPAGE="https://gitlab.gnome.org/GNOME/calls"
+GITLAB="https://gitlab.gnome.org"
+SRC_URI="
+	${GITLAB}/GNOME/${MY_PN}/-/archive/v${PV}/${MY_P}.tar.bz2
+	${GITLAB}/World/Phosh/libcall-ui/-/archive/v${LCU_V}/libcall-ui-v${LCU_V}.tar.bz2
+"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="CC0-1.0 CC-BY-SA-4.0 GPL-3+ LGPL-2+ LGPL-2.1+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64"
+IUSE="gtk-doc man"
+
+RDEPEND="
+	app-crypt/libsecret[introspection,vala]
+	dev-libs/feedbackd[introspection,vala]
+	dev-libs/folks:=
+	dev-libs/glib:2
+	dev-libs/gom[introspection]
+	dev-libs/libgee:0.8=[introspection]
+	dev-libs/libpeas
+	gnome-extra/evolution-data-server:=[vala]
+	gui-libs/libhandy:1[introspection,vala]
+	media-libs/gstreamer:1.0[introspection]
+	media-sound/callaudiod
+	net-libs/sofia-sip
+	net-misc/modemmanager:=[introspection]
+	x11-libs/gtk+:3
+"
+DEPEND="${RDEPEND}
+	test? ( media-plugins/gst-plugins-srtp:1.0 )
+"
+BDEPEND="
+	$(vala_depend)
+	dev-libs/gobject-introspection
+	dev-libs/protobuf
+	dev-util/wayland-scanner
+	gtk-doc? ( dev-util/gtk-doc )
+	man? ( dev-python/docutils )
+"
+
+src_unpack() {
+	default
+
+	cd "${S}" || die
+	rmdir subprojects/libcall-ui || die
+	mv "${WORKDIR}"/libcall-ui-v${LCU_V} subprojects/libcall-ui || die
+}
+
+src_prepare() {
+	default
+	vala_setup
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use gtk-doc gtk_doc)
+		$(meson_use man manpages)
+		$(meson_use test tests)
+	)
+	meson_src_configure
+}
+
+src_test() {
+	local tests=(
+		calls:call
+		calls:contacts
+		calls:dbus
+		calls:manager
+		calls:media
+		calls:origin
+		calls:plugins
+		calls:provider
+		calls:sdp-crypto
+		calls:settings
+		calls:srtp
+		calls:ui-call
+		calls:util
+
+		# TODO: needs working sound card
+		#calls:application
+
+		# TODO: failure related to feedbackd
+		#calls:ringer
+
+		# TODO: hangs
+		#calls:sip
+	)
+	virtx meson_src_test "${tests[@]}"
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+
+	optfeature "SRTP support" media-plugins/gst-plugins-srtp
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}