From bce52275cd2a8d939f87c3da1c5c20522fb04886 Mon Sep 17 00:00:00 2001
From: Gerben Jan Dijkman <gjdijkman@gjdwebserver.nl>
Date: Sun, 6 Oct 2024 15:10:14 +0200
Subject: [PATCH] Version bump

---
 dev-libs/feedbackd/feedbackd-0.5.0.ebuild | 80 +++++++++++++++++++++++
 1 file changed, 80 insertions(+)
 create mode 100644 dev-libs/feedbackd/feedbackd-0.5.0.ebuild

diff --git a/dev-libs/feedbackd/feedbackd-0.5.0.ebuild b/dev-libs/feedbackd/feedbackd-0.5.0.ebuild
new file mode 100644
index 0000000..1069478
--- /dev/null
+++ b/dev-libs/feedbackd/feedbackd-0.5.0.ebuild
@@ -0,0 +1,80 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+VALA_USE_DEPEND="vapigen"
+
+inherit meson udev vala verify-sig
+
+DESCRIPTION="A daemon to provide haptic feedback on events"
+HOMEPAGE="https://source.puri.sm/Librem5/feedbackd"
+SRC_URI="https://sources.phosh.mobi/releases/${PN}/${P}.tar.xz
+	verify-sig? ( https://sources.phosh.mobi/releases/${PN}/${P}.tar.xz.asc )"
+
+LICENSE="LGPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+IUSE="+daemon gtk-doc +introspection man test +vala"
+
+REQUIRED_USE="vala? ( introspection )"
+RESTRICT="!test? ( test )"
+
+DEPEND="
+	dev-libs/glib:2
+	dev-libs/gmobile
+	daemon? (
+		dev-libs/json-glib
+		dev-libs/libgudev
+		media-libs/gsound
+	)
+	introspection? ( dev-libs/gobject-introspection )
+"
+RDEPEND="${DEPEND}
+	dev-libs/feedbackd-device-themes
+"
+BDEPEND="
+	dev-util/gdbus-codegen
+	gtk-doc? ( dev-util/gi-docgen )
+	man? ( dev-python/docutils )
+	vala? ( $(vala_depend) )
+	verify-sig? ( sec-keys/openpgp-keys-phosh )
+"
+
+VERIFY_SIG_OPENPGP_KEY_PATH="/usr/share/openpgp-keys/phosh.asc"
+
+src_prepare() {
+	default
+
+	use vala && vala_setup
+	sed -i 's/-G feedbackd/-G video/g' debian/feedbackd.udev || die
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_feature introspection)
+		$(meson_use daemon)
+		$(meson_use gtk-doc gtk_doc)
+		$(meson_use man)
+		$(meson_use test tests)
+		$(meson_use vala vapi)
+	)
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+	udev_newrules debian/feedbackd.udev 90-feedbackd
+
+	if use gtk-doc; then
+		mkdir -p "${ED}"/usr/share/gtk-doc/html/ || die
+		mv "${ED}"/usr/share/doc/libfeedback-${SLOT} "${ED}"/usr/share/gtk-doc/html/ || die
+	fi
+}
+
+pkg_postinst() {
+	udev_reload
+}
+
+pkg_postrm() {
+	udev_reload
+}