Added

media-sound/gnome-sound-recorder/Manifest

@@ -0,0 +1 @@
+DIST gnome-sound-recorder-40.0.tar.xz 199056 BLAKE2B e830b746ccf9e038a6f425dee9a6ef8eb88cd849659570c11364b833b0be8c7e7302c0b20e8c853d7228a589d6e3953fecf2fddb31304a1905678aa99b461248 SHA512 28de1dbb9251c834513be55c3f4107cd014d74e634e383e6feb3b9430ff562e19d29e9abcd566b0fc0ed1ec3841add0f694b47c51fe91a3b4ba33b9f43a0d617

media-sound/gnome-sound-recorder/gnome-sound-recorder-40.0.ebuild

@@ -0,0 +1,50 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{7..9} )
+
+inherit gnome.org gnome2-utils meson python-any-r1 xdg
+
+DESCRIPTION="Simple sound recorder"
+HOMEPAGE="https://wiki.gnome.org/Design/Apps/SoundRecorder"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~arm ~arm64"
+
+DEPEND="
+	>=dev-libs/gjs-1.54.0
+	>=dev-libs/glib-2.46:2
+	>=x11-libs/gtk+-3.12:3[introspection]
+	media-libs/gst-plugins-bad:1.0
+	>=gui-libs/libhandy-1.1.90:1=
+	>=dev-libs/gobject-introspection-1.31.6
+	x11-libs/gdk-pixbuf:2[introspection]
+"
+RDEPEND="${DEPEND}
+	media-libs/gstreamer:1.0[introspection]
+	media-libs/gst-plugins-base:1.0[introspection,ogg]
+	media-libs/gst-plugins-good:1.0
+	media-plugins/gst-plugins-flac:1.0
+	media-plugins/gst-plugins-pulse:1.0
+"
+BDEPEND="
+	${PYTHON_DEPS}
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+"
+
+pkg_setup() {
+	python-any-r1_pkg_setup
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}