Added the eselect

app-eselect/eselect-gnome-shell-extensions/Manifest

@@ -0,0 +1 @@
+DIST eselect-gnome-shell-extensions-20180306.tar.xz 2676 BLAKE2B 846e282f99828ce795ba98557bb97301f576895c46e98ae0c079dfee8461146756c85573c1ce24e4ca3690d2ea8383dd988e40d3fe271a32b1987e027b47e3ae SHA512 2c0b9119219d8f3c54201f9865e1a9dd6889ccf26537802c591e89adb545f38aca13fa6b1119fe52d4183daf4adb6d2b1053b252d2756778b31626688092196d

app-eselect/eselect-gnome-shell-extensions/eselect-gnome-shell-extensions-20180306.ebuild

@@ -0,0 +1,48 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+DESCRIPTION="Manages system defaults for GNOME Shell extensions"
+HOMEPAGE="https://wiki.gentoo.org/wiki/No_homepage"
+SRC_URI="https://dev.gentoo.org/~leio/distfiles/${P}.tar.xz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~arm ~arm64"
+
+# gnome-shell schemas are used in pkg_postinst
+COMMON_DEPEND="app-admin/eselect
+	>=dev-libs/glib-2.26:2
+	gnome-base/gsettings-desktop-schemas
+	gnome-base/gnome-shell"
+RDEPEND="${COMMON_DEPEND}
+	dev-lang/perl
+	dev-perl/JSON"
+DEPEND="${COMMON_DEPEND}
+	app-arch/xz-utils"
+
+src_install() {
+	insinto "/usr/share/eselect/modules"
+	doins gnome-shell-extensions.eselect
+	keepdir "/etc/eselect/gnome-shell-extensions"
+	# The actual gschema override file will be created in pkg_postinst.
+	dosym "../../../../etc/eselect/gnome-shell-extensions/${PN}.gschema.override" \
+		"/usr/share/glib-2.0/schemas/${PN}.gschema.override"
+}
+
+pkg_postinst() {
+	einfo "Updating list of installed extensions"
+	eselect gnome-shell-extensions update || die
+	local keyname="disabled-extensions"
+	has_version ">=gnome-base/gnome-shell-3.1.90" &&
+		keyname="enabled-extensions"
+	elog
+	elog "eselect gnome-shell-extensions manages the system default value of"
+	elog "the org.gnome.shell ${keyname} key. To override the default"
+	elog "for an individual user, use the gsettings command, e.g."
+	elog "\$ gsettings set org.gnome.shell ${keyname} \"['foo', 'bar']\""
+	elog "To undo per-user changes and use the system default, do"
+	elog "\$ gsettings reset org.gnome.shell ${keyname}"
+	elog
+}