Added Gmobile

dev-libs/feedbackd/Manifest

@@ -1,2 +0,0 @@
-DIST feedbackd-v0.3.0.tar.bz2 82391 BLAKE2B 33835754e451277fe41d9dd319d76db6a81a6965e9aeff7620397c398b3bcd0c4f4962a336a16f8b954e67df49506bb79b8363ec316c85fedf92c824d59d749e SHA512 8811b911661197d6fa9ff4d0e5df16f537e5e3727e1ed8cd59eea7f647a552cab221fde28e5ca9fb755e41486e199c087dfdcfecf4588fdced523fce9f9262c1
-DIST gmobile-d483537aee4778b114ce5d50c4c8a9f8d58337ed.tar.bz2 20337 BLAKE2B f94295672ed699f308ccfab3835ed6c7f1184c0e267ea1c2ab7b6d59c98b3d027b300bf6d29db6442de20cec852f5c1031d1b09f220e94afc79c48566c160676 SHA512 86acabbffb1b5f98f2b132ce5bd12940769c11ed53d38401a0048216943a4b095bd230774d83444e7b5f5d26825f32ced0075dce7354f6fa486d47ef5f86b4f3

dev-libs/feedbackd/Manifest (1)

@@ -0,0 +1,4 @@
+DIST feedbackd-0.3.0.tar.xz 106640 BLAKE2B 03c5d11422891d2c36c07e07e3ea705de0e5fca0e759bd2cfd481959c7782a63b76b79e11cdf3f37d50b22a9deeab79a30faefefdc399fb0d2ea544d76532e96 SHA512 243ee56cb96541181fc2ae614ae80be694dc1d7cf3a240927f843efb7c8736e0c4ca227af8872ed3caad68ff896c5339ea3f4148099f5327a16ca0c95346d996
+DIST feedbackd-0.3.0.tar.xz.asc 833 BLAKE2B 85979a8d0dc2be4fa4f0ba9ee3bf02b05415aafed62b259a1dbd2bbd5c8b09b447bfa33d4909f2ed08060f3cbdaf5610a9a0c3e60784577155e12553650fbe00 SHA512 d17c3374a522c76a86bbae0fdb920e5372d48336890d1616e693f157ff5b5949152ff83b6ce5710c4d147d0265cb3b430cbc4bb4dc091e1910badbd831655019
+DIST feedbackd-v0.2.0.tar.bz2 76695 BLAKE2B 81928442f05c0623eba46aa37ba1957c216d8d7fe8bd89b55a3ab4928d3b95c4792ee30325f878eb9bce82ee262219233b9cdc3e086c1954e7811d5574b9ecaf SHA512 d758cd135b10b76fd35b64a66ec46261fc66be75095898a6592f4efdea7a9f94a850c654e63cde028e9f80cc7f180396d7e1fe46222611c5140b2116ac04ca6d
+DIST gmobile-d483537aee4778b114ce5d50c4c8a9f8d58337ed.tar.bz2 20337 BLAKE2B f94295672ed699f308ccfab3835ed6c7f1184c0e267ea1c2ab7b6d59c98b3d027b300bf6d29db6442de20cec852f5c1031d1b09f220e94afc79c48566c160676 SHA512 86acabbffb1b5f98f2b132ce5bd12940769c11ed53d38401a0048216943a4b095bd230774d83444e7b5f5d26825f32ced0075dce7354f6fa486d47ef5f86b4f3

dev-libs/feedbackd/feedbackd-0.2.0.ebuild

@@ -0,0 +1,84 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+VALA_USE_DEPEND="vapigen"
+
+inherit vala meson udev
+
+GMOBILE_COMMIT="d483537aee4778b114ce5d50c4c8a9f8d58337ed"
+DESCRIPTION="A daemon to provide haptic feedback on events"
+HOMEPAGE="https://source.puri.sm/Librem5/feedbackd"
+SRC_URI="
+	https://source.puri.sm/Librem5/${PN}/-/archive/v${PV}/${PN}-v${PV}.tar.bz2
+	https://gitlab.gnome.org/guidog/gmobile/-/archive/${GMOBILE_COMMIT}.tar.bz2 -> gmobile-${GMOBILE_COMMIT}.tar.bz2
+"
+S="${WORKDIR}/${PN}-v${PV}"
+
+LICENSE="LGPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+IUSE="+daemon gtk-doc +introspection man test +vala"
+REQUIRED_USE="vala? ( introspection )"
+RESTRICT="!test? ( test )"
+
+DEPEND="
+	dev-libs/glib:2
+	daemon? (
+		dev-libs/json-glib
+		dev-libs/libgudev
+		media-libs/gsound
+	)
+	introspection? ( dev-libs/gobject-introspection )
+"
+RDEPEND="${DEPEND}
+	dev-libs/feedbackd-device-themes
+"
+BDEPEND="
+	dev-util/gdbus-codegen
+	gtk-doc? ( dev-util/gi-docgen )
+	man? ( dev-python/docutils )
+	vala? ( $(vala_depend) )
+"
+
+src_prepare() {
+	default
+
+	if use daemon; then
+		rmdir "${S}/subprojects/gmobile" || die
+		mv "${WORKDIR}/gmobile-${GMOBILE_COMMIT}" "${S}/subprojects/gmobile" || die
+	fi
+
+	use vala && vala_setup
+	sed -i 's/-G feedbackd/-G video/g' debian/feedbackd.udev || die
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_feature introspection)
+		$(meson_use daemon)
+		$(meson_use gtk-doc gtk_doc)
+		$(meson_use man)
+		$(meson_use test tests)
+		$(meson_use vala vapi)
+	)
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+	udev_newrules debian/feedbackd.udev 90-feedbackd
+
+	if use gtk-doc; then
+		mkdir -p "${ED}"/usr/share/gtk-doc/html/ || die
+		mv "${ED}"/usr/share/doc/libfeedback-${SLOT} "${ED}"/usr/share/gtk-doc/html/ || die
+	fi
+}
+
+pkg_postinst() {
+	udev_reload
+}
+
+pkg_postrm() {
+	udev_reload
+}

dev-libs/feedbackd/feedbackd-0.3.0.ebuild

@@ -4,24 +4,24 @@
 EAPI=8
 VALA_USE_DEPEND="vapigen"
 
-inherit vala meson udev
+inherit meson udev vala verify-sig
 
 DESCRIPTION="A daemon to provide haptic feedback on events"
 HOMEPAGE="https://source.puri.sm/Librem5/feedbackd"
-SRC_URI="
+SRC_URI="https://sources.phosh.mobi/releases/${PN}/${P}.tar.xz
-	https://source.puri.sm/Librem5/${PN}/-/archive/v${PV}/${PN}-v${PV}.tar.bz2
+	verify-sig? ( https://sources.phosh.mobi/releases/${PN}/${P}.tar.xz.asc )"
-"
-S="${WORKDIR}/${PN}-v${PV}"
 
 LICENSE="LGPL-3"
-KEYWORDS="~amd64 ~arm ~arm64 ~x86"
 SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
 IUSE="+daemon gtk-doc +introspection man test +vala"
+
 REQUIRED_USE="vala? ( introspection )"
 RESTRICT="!test? ( test )"
 
 DEPEND="
 	dev-libs/glib:2
+	dev-libs/gmobile
 	daemon? (
 		dev-libs/json-glib
 		dev-libs/libgudev
@@ -37,15 +37,14 @@ BDEPEND="
 	gtk-doc? ( dev-util/gi-docgen )
 	man? ( dev-python/docutils )
 	vala? ( $(vala_depend) )
+	verify-sig? ( sec-keys/openpgp-keys-phosh )
 "
 
+VERIFY_SIG_OPENPGP_KEY_PATH="/usr/share/openpgp-keys/phosh.asc"
+
 src_prepare() {
 	default
 
-	if use daemon; then
-		mv "${WORKDIR}/gmobile-${GMOBILE_COMMIT}" "${S}/subprojects/gmobile" || die
-	fi
-
 	use vala && vala_setup
 	sed -i 's/-G feedbackd/-G video/g' debian/feedbackd.udev || die
 }

dev-libs/gmobile/Manifest

@@ -0,0 +1,2 @@
+DIST gmobile-0.1.0.tar.xz 45044 BLAKE2B 90d9efaf4383392fc55c15540ae7b600cea486750885d22df467fb20ade748d28784856301fbdd614a9148dbc40f015a8f8a8369dff310f54e95e1468b8c966d SHA512 eb17d0b39d5dbe197a2502fe974af37076317094c4759bbc4924d951fdb1bdb1fe8f13a85419dad756954c165bbd6dfca4ce555f6e3f5a3def4bac8bc913ab1a
+DIST gmobile-0.1.0.tar.xz.asc 833 BLAKE2B 30c6a97e78cb03beda468e1759d73d55892f61785adcde390195b0089df039a2c50882e0f22d2db925a324af0869d659d6c9dc71f405bfd608a07521481e261b SHA512 a90ff042dcd6e26508e9927a92c3ab537ca9556a758e2064d0a480c11b83c1355f6422f9e2ee0a51dc4e28355ef9b626b0c0388ed59363c42581037d5b781080

dev-libs/gmobile/gmobile-0.1.0.ebuild

@@ -0,0 +1,54 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+VALA_USE_DEPEND="vapigen"
+
+inherit meson verify-sig
+
+DESCRIPTION="Mobile related helpers for glib based projects"
+HOMEPAGE="https://gitlab.gnome.org/World/Phosh/gmobile/"
+SRC_URI="https://sources.phosh.mobi/releases/${PN}/${P}.tar.xz
+	verify-sig? ( https://sources.phosh.mobi/releases/${PN}/${P}.tar.xz.asc )"
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+IUSE="gtk-doc +introspection test"
+RESTRICT="!test? ( test )"
+
+DEPEND="
+	>=dev-libs/glib-2.66:2
+	>=dev-libs/json-glib-1.6.2
+	introspection? ( dev-libs/gobject-introspection )
+"
+RDEPEND="${DEPEND}"
+BDEPEND="
+	gtk-doc? ( >=dev-util/gi-docgen-2021.1 )
+	verify-sig? ( sec-keys/openpgp-keys-phosh )
+"
+
+VERIFY_SIG_OPENPGP_KEY_PATH="/usr/share/openpgp-keys/phosh.asc"
+
+src_configure() {
+	local emesonargs=(
+		-Dexamples=false
+		$(meson_use gtk-doc gtk_doc)
+		$(meson_use introspection)
+		$(meson_use test tests)
+	)
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+
+	# https://bugs.gentoo.org/930407
+	find "${ED}"/usr/$(get_libdir) -name "*.a" -delete || die
+
+	if use gtk-doc; then
+		local gtkdocdir="${ED}/usr/share/gtk-doc/html/"
+		mkdir -p "${gtkdocdir}" || die
+		mv "${ED}"/usr/share/doc/${PN}-${SLOT} "${gtkdocdir}" || die
+	fi
+}

dev-libs/gmobile/metadata.xml

@@ -0,0 +1,15 @@
+<?xml version='1.0' encoding='UTF-8'?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person">
+		<email>cyber+gentoo@sysrq.in</email>
+		<name>Anna</name>
+	</maintainer>
+	<upstream>
+		<maintainer>
+			<name>Guido Günther</name>
+			<email>agx@sigxcpu.org</email>
+		</maintainer>
+		<remote-id type="gnome-gitlab">World/Phosh</remote-id>
+	</upstream>
+</pkgmetadata>