Added

net-lib/rest/Manifest

@@ -0,0 +1,2 @@
+DIST rest-0.8.1.tar.xz 333376 BLAKE2B 595576f29ebe35121b7a896086abd3411ac3b2d324d2e50d646274c4060cfaffbd3b701eaae80afdc60d52c77bb5076135064648536378f2562f27c79c5738b7 SHA512 824a341db3827e4360abe03e33735918c68913c70d797699ef74271080a1985872006ec70fd994dc8fa3fbfef417e6fe979883c11286512d0ce623b8368e40c3
+DIST rest-0.9.1.tar.xz 71136 BLAKE2B 696a43db8a05d90cd2cb86cb2ffe22a817c7b0565c1e90e2508b0dffd3824fa46afef78c039d8911dc50f93c0afe1efbc783676c677b71bb7a2b5ad9ac5a1a26 SHA512 7fb219f571aec2b8d09d71e257e2b230bfb5c862e7e425fd540c96f6e2a22457df7d3df32838d71beec00ba54c7adbd0301d744bb0497c46b3a1413949304462

net-lib/rest/rest-0.9.1.ebuild

@@ -0,0 +1,59 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit gnome.org meson vala
+
+DESCRIPTION="Helper library for RESTful services"
+HOMEPAGE="https://wiki.gnome.org/Projects/Librest"
+
+LICENSE="LGPL-2.1"
+SLOT="1.0" # librest_soversion
+KEYWORDS="~amd64 ~arm64"
+IUSE="gtk-doc +introspection test vala"
+REQUIRED_USE="
+	gtk-doc? ( introspection )
+	vala? ( introspection )
+"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-libs/glib-2.44.0:2
+	>=net-libs/libsoup-2.99.2:3.0
+	dev-libs/json-glib:0[introspection?]
+	dev-libs/libxml2:2
+	app-misc/ca-certificates
+	introspection? ( >=dev-libs/gobject-introspection-1.74.0:= )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	dev-util/glib-utils
+	gtk-doc? ( >=dev-util/gi-docgen-2021.6 )
+	vala? ( $(vala_depend) )
+"
+
+src_prepare() {
+	default
+	vala_setup
+
+	# The only two tests from the rest-extras suite (flickr and lastfm) require
+	# network access
+	if has network-sandbox ${FEATURES}; then
+		sed -i -e '/flickr/d' -e '/lastfm/d' tests/meson.build
+	fi
+}
+
+src_configure() {
+	local emesonargs=(
+		-Dca_certificates=true
+		-Dca_certificates_path="${EPREFIX}"/etc/ssl/certs/ca-certificates.crt
+		$(meson_use introspection)
+		$(meson_use vala vapi)
+		-Dexamples=false
+		$(meson_use gtk-doc gtk_doc)
+		-Dsoup2=false
+		$(meson_use test tests)
+	)
+	meson_src_configure
+}