Version bump

net-voip/gnome-calls/Manifest

@@ -1,2 +1,3 @@
 DIST calls-v46.0.tar.gz 571413 BLAKE2B 5bfa0a6781d5e6735343319e2a868008e12170491103f066ffba68b6a760a14ab09ef1cddfa71ceba4768bd4b23253846b9d03a894874e7ec9fccc3d18db97c7 SHA512 765d38a1c86e91207f6c2ce29a79233986886d8901c6917dea82072beab4b3104543a90b46b87bc967e63e69f99c57e77c1da842b3bf600553788a9ef5dc7818
+DIST calls-v46.3.tar.gz 576242 BLAKE2B 787c4daf2d7bd748bf6206fb9522df756e8c6eb0514b91e6a5b0f833d91feb9139ce75f9931a66a228cd2ab3a0259cc30a6bcd1da7b8324aa1cd661609a555a7 SHA512 a7389079e969ad340770123b90e0cfb73db3992cbd189e3761937cd6f6de6835b857d50f7e37f9243cdf0abbc88d5513da4ad41662c603390f4e9fb0db41e700
 DIST libcall-ui-7ff3e6649a2ef44bc96d3179cd8b1dac2fdd681d.tar.gz 170731 BLAKE2B 21e397d6e7d3a20bfd5a8a459f49b5aef0a98d45a4202b6c98813858292d0215ab756d0a58c794cd296cc863cf9a5d42988e1b2fa68dfd4f8a53c348c27b3ada SHA512 b7463577d4032566d6e28bf98e442132a2db9f758f0ea4be76d6dc896a2c32cef2ce4f3a5184860978692a031bd43272489b1cec2b2be9030b1dccf3cc6fa919

net-voip/gnome-calls/gnome-calls-46.3.ebuild

@@ -0,0 +1,112 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+VALA_USE_DEPEND="vapigen"
+
+inherit vala meson gnome2-utils optfeature virtualx xdg
+
+LCU_COMMIT="7ff3e6649a2ef44bc96d3179cd8b1dac2fdd681d"
+DESCRIPTION="Phone dialer and call handler"
+HOMEPAGE="https://gitlab.gnome.org/GNOME/calls"
+SRC_URI="
+	https://gitlab.gnome.org/GNOME/calls/-/archive/v${PV}/calls-v${PV}.tar.gz
+	https://gitlab.gnome.org/World/Phosh/libcall-ui/-/archive/${LCU_COMMIT}/libcall-ui-${LCU_COMMIT}.tar.gz
+"
+
+LICENSE="CC0-1.0 CC-BY-SA-4.0 GPL-3+ LGPL-2+ LGPL-2.1+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64"
+IUSE="gtk-doc man"
+
+RDEPEND="
+	app-crypt/libsecret[introspection,vala]
+	dev-libs/feedbackd[introspection,vala]
+	dev-libs/folks:=
+	dev-libs/glib:2
+	dev-libs/gom[introspection]
+	dev-libs/libgee:0.8=[introspection]
+	dev-libs/libpeas
+	gnome-extra/evolution-data-server:=[vala]
+	gui-libs/libhandy:1[introspection,vala]
+	media-libs/gstreamer:1.0[introspection]
+	media-sound/callaudiod
+	net-libs/sofia-sip
+	net-misc/modemmanager:=[introspection]
+	x11-libs/gtk
+"
+DEPEND="${RDEPEND}
+	test? ( media-plugins/gst-plugins-srtp:1.0 )
+"
+BDEPEND="
+	$(vala_depend)
+	dev-libs/gobject-introspection
+	dev-libs/protobuf
+	dev-util/wayland-scanner
+	gtk-doc? ( dev-util/gtk-doc )
+	man? ( dev-python/docutils )
+"
+
+S="${WORKDIR}/calls-v${PV}"
+
+
+src_unpack() {
+	default
+	rm -r "${S}"/subprojects/libcall-ui || die
+	mv "${WORKDIR}"/libcall-ui-"${LCU_COMMIT}" "${S}"/subprojects/libcall-ui || die
+	
+}
+
+src_prepare() {
+	default
+	vala_setup
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use gtk-doc gtk_doc)
+		$(meson_use man manpages)
+		$(meson_use test tests)
+	)
+	meson_src_configure
+}
+
+src_test() {
+	local tests=(
+		calls:call
+		calls:contacts
+		calls:dbus
+		calls:manager
+		calls:media
+		calls:origin
+		calls:plugins
+		calls:provider
+		calls:ringer
+		calls:sdp-crypto
+		calls:settings
+		calls:srtp
+		calls:ui-call
+		calls:util
+
+		# TODO: needs working sound card
+		#calls:application
+
+		# TODO: hangs
+		#calls:sip
+	)
+	virtx meson_src_test "${tests[@]}"
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+
+	optfeature "SRTP support" media-plugins/gst-plugins-srtp
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}
+
+