Added Gnome clocks

gnome-extra/gnome-clocks/Manifest

@@ -0,0 +1 @@
+DIST gnome-clocks-40.0.tar.xz 378584 BLAKE2B 9521e6fbb048364f2cc678ea6e3e235d1b1fbdf214785ab2f5b1cfc87b8225f6ce55197459571dc762a3a0c18cc49a002bb4aa7a509fd229942686bf46d097f2 SHA512 7d117a7faead25d7f68dded7bbde650a61b2765fc2d22774dc2e7673fa0f711c8a59ac79c88b2dfdc70fc80277110c987e387fa7e95ce6c6b95f1efd5f392e85

gnome-extra/gnome-clocks/gnome-clocks-40.0.ebuild

@@ -0,0 +1,56 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit gnome.org gnome2-utils meson vala xdg
+
+DESCRIPTION="Clocks application for GNOME"
+HOMEPAGE="https://wiki.gnome.org/Apps/Clocks"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~arm ~arm64"
+IUSE=""
+
+RDEPEND="
+	>=dev-libs/glib-2.58:2
+	>=x11-libs/gtk+-3.20:3
+	>=media-libs/gsound-0.98
+	>=dev-libs/libgweather-3.32.0:2=
+	>=gnome-base/gnome-desktop-3.8:3=
+	>=sci-geosciences/geocode-glib-1
+	>=app-misc/geoclue-2.4:2.0
+	>=gui-libs/libhandy-1.0.0:1
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	dev-libs/libxml2:2
+	dev-util/itstool
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+	$(vala_depend)
+	dev-libs/libgweather:2[vala]
+	media-libs/gsound[vala]
+	gui-libs/libhandy:1[vala]
+"
+
+DOCS=( AUTHORS.md CONTRIBUTING.md README.md )
+
+src_prepare() {
+	xdg_src_prepare
+	vala_src_prepare
+}
+
+src_configure() {
+	meson_src_configure -Dprofile=default
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}