# Copyright 1999-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8
VALA_USE_DEPEND="vapigen"

inherit vala meson gnome2-utils optfeature virtualx xdg

LCU_COMMIT="6798b38d4d66d069751151b3e9a202c6de8d7f3c"
DESCRIPTION="Phone dialer and call handler"
HOMEPAGE="https://gitlab.gnome.org/GNOME/calls"
SRC_URI="
	https://gitlab.gnome.org/GNOME/calls/-/archive/v${PV}/calls-v${PV}.tar.gz
	https://gitlab.gnome.org/World/Phosh/libcall-ui/-/archive/${LCU_COMMIT}/libcall-ui-${LCU_COMMIT}.tar.gz
"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64 ~arm64"
IUSE="+introspection +vala gtk-doc man""
REQUIRED_USE="vala? ( introspection )"

RDEPEND="
	app-crypt/libsecret[introspection,vala]
	dev-libs/feedbackd[introspection,vala]
	dev-libs/folks:=
	dev-libs/glib:2
	dev-libs/gom[introspection]
	dev-libs/libgee:0.8=[introspection]
	dev-libs/libpeas
	gnome-extra/evolution-data-server:=[vala,phonenumber]
	gui-libs/libhandy:1[introspection,vala]
	media-libs/gstreamer:1.0[introspection]
	media-sound/callaudiod
	net-libs/sofia-sip
	net-misc/modemmanager:=[introspection]
	x11-libs/gtk+:3
"
DEPEND="${RDEPEND}
	test? ( media-plugins/gst-plugins-srtp:1.0 )
"
BDEPEND="
	$(vala_depend)
	dev-libs/gobject-introspection
	dev-libs/protobuf
	dev-util/wayland-scanner
	gtk-doc? ( dev-util/gtk-doc )
	man? ( dev-python/docutils )
"

S="${WORKDIR}/calls-v${PV}"

src_unpack() {
	default

	rm -r "${S}"/subprojects/libcall-ui || die
	mv "${WORKDIR}"/libcall-ui-"${LCU_COMMIT}" "${S}"/subprojects/libcall-ui || die
}

src_prepare() {
	default
	vala_setup
}

src_configure() {
	local emesonargs=(
		$(meson_use gtk-doc gtk_doc)
		$(meson_use man manpages)
		$(meson_use test tests)
	)
	meson_src_configure
}

src_test() {
	local tests=(
		calls:call
		calls:contacts
		calls:dbus
		calls:manager
		calls:media
		calls:origin
		calls:plugins
		calls:provider
		calls:ringer
		calls:sdp-crypto
		calls:settings
		calls:srtp
		calls:ui-call
		calls:util

		# TODO: needs working sound card
		#calls:application

		# TODO: hangs
		#calls:sip
	)
	virtx meson_src_test "${tests[@]}"
}

ppkg_postinst() {
	xdg_pkg_postinst
	gnome2_schemas_update

	optfeature "SRTP support" media-plugins/gst-plugins-srtp
}

pkg_postrm() {
	xdg_pkg_postrm
	gnome2_schemas_update
}