Added libaxc

net-libs/libaxc/Manifest

@@ -0,0 +1 @@
+DIST libaxc-0.3.4.tar.gz 40198 BLAKE2B 78fc122eefbc5c6173bdad5cf31734cf95b750c09bddede5b2656a88bede3d6c25fb22af5447681c58eb1f296ee326480e22aacb843d951f1bd7a6933155432a SHA512 7b6b5466ee89d78d3c3a2e7cf961dfb3310bff01947e69e906c83ff97e89d1bdc0e2e92f7bd0d4b48a97af91409f435a4fd869229af5b67b2f66ba464bbfd7b8

net-libs/libaxc/libaxc-0.3.4-r2.ebuild

@@ -0,0 +1,66 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+MY_P="axc-${PV}"
+DESCRIPTION="Client library for libsignal-protocol-c"
+HOMEPAGE="https://github.com/gkdr/axc"
+SRC_URI="https://github.com/gkdr/axc/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3"  # not GPL-3+
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~arm64 ~arm"
+IUSE="static-libs test"
+
+RDEPEND="
+	dev-db/sqlite
+	dev-libs/glib
+	dev-libs/libgcrypt
+	net-libs/libsignal-protocol-c
+	"
+DEPEND="
+	${RDEPEND}
+	virtual/pkgconfig
+	test? ( dev-util/cmocka )
+	"
+
+S="${WORKDIR}"/${MY_P}
+RESTRICT="!test? ( test )"
+
+PATCHES=(
+	"${FILESDIR}"/${P}-so-symlinks.patch
+)
+
+DOCS=( CHANGELOG.md README.md )
+
+src_prepare() {
+	rm -R lib || die  # unbundle libsignal-protocol-c
+	default
+}
+
+src_compile() {
+	emake PREFIX=/usr
+}
+
+src_install() {
+	emake DESTDIR="${D}" PREFIX=/usr install
+
+	# Respect libdir other than /usr/lib, e.g. /usr/lib64
+	local libdir="$(get_libdir)"
+	if [[ ${libdir} != lib ]]; then
+		mv "${D}"/usr/{lib,${libdir}} || die
+		sed "s|^libdir=.*|libdir=\${prefix}/${libdir}|" \
+				-i "${D}/usr/${libdir}/pkgconfig/libaxc.pc" || die
+	fi
+
+	einstalldocs
+
+	if ! use static-libs ; then
+		rm "${D}/usr/${libdir}/libaxc.a" || die
+	fi
+}
+
+src_test() {
+	emake -j1 test
+}