gjdwebserver/gjdwebserver-overlay
gjdwebserver/gjdwebserver-overlay
3
0
Fork 0
Code Pull Requests Releases Activity

Version bump

Browse Source
This commit is contained in:
Gerben Jan Dijkman 2023-05-02 16:08:16 +02:00
parent 8f03e395f8
commit 77e0381d01
2 changed files with 87 additions and 2 deletions
Show Stats Download Patch File Download Diff File Expand all files Collapse all files

5
dev-libs/feedbackd/Manifest
View File

@ -1,2 +1,3 @@
DIST feedbackd-v0.1.1.tar.gz 94919 BLAKE2B bff7e8c89f0f915aeee4871af12ffad1752e722b87c48b1296e675d7520a7d59d0b5b2ac897187c5f6ff4ba2c562eb9352862711b51eb57690c6cd5d92e57c28 SHA512 6c6dea73f922bb7b48e15d6e2d1b6c8ab4beb3b9ea81d7824a826be0293a2d8ab685fe9b4414d07d4c312b277640953d19cf2106882e5c1b5d85c982b8446d40
DIST gmobile-d483537aee4778b114ce5d50c4c8a9f8d58337ed.tar.gz 22257 BLAKE2B b9b884fe58e35ae6f08a3f53734deb8450116dae9bf4e698d793355bb1d3a7ddcd3d519bbb7eb3757e5a35833c5ec2a742a2ba3a6c4e2725864e8d78e17215c3 SHA512 abb6b06c5778bc225abedf8faf24980359255c345be794e59c4da63c80098c26dbd32cf19dc2969fe6555b8748784dfa51fe5399f12892f96ae14fee9c75fa9a
DIST feedbackd-v0.1.1.tar.bz2 76231 BLAKE2B 0ef5b501d8619cc1278d6469ffeb91b65303a5601387665606fb14a2edb83e7a0f2cc3be84e0fbe496f0f482fba6bb4d0c8444ee2c4356f7af787dff7a30cc64 SHA512 6f7ef65b156504665d4f0eba73c2b4209f4f3c8bd41a46e367a0dde4fbe9e1cabbc9e237a1b3bb399fba847c47717db11295766a34f8ba58cf8f32a07b333a80
DIST feedbackd-v0.2.0.tar.bz2 76695 BLAKE2B 81928442f05c0623eba46aa37ba1957c216d8d7fe8bd89b55a3ab4928d3b95c4792ee30325f878eb9bce82ee262219233b9cdc3e086c1954e7811d5574b9ecaf SHA512 d758cd135b10b76fd35b64a66ec46261fc66be75095898a6592f4efdea7a9f94a850c654e63cde028e9f80cc7f180396d7e1fe46222611c5140b2116ac04ca6d
DIST gmobile-d483537aee4778b114ce5d50c4c8a9f8d58337ed.tar.bz2 20337 BLAKE2B f94295672ed699f308ccfab3835ed6c7f1184c0e267ea1c2ab7b6d59c98b3d027b300bf6d29db6442de20cec852f5c1031d1b09f220e94afc79c48566c160676 SHA512 86acabbffb1b5f98f2b132ce5bd12940769c11ed53d38401a0048216943a4b095bd230774d83444e7b5f5d26825f32ced0075dce7354f6fa486d47ef5f86b4f3

84
dev-libs/feedbackd/feedbackd-0.2.0.ebuild Normal file
View File

@ -0,0 +1,84 @@
# Copyright 1999-2023 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
VALA_USE_DEPEND="vapigen"
inherit vala meson udev
GMOBILE_COMMIT="d483537aee4778b114ce5d50c4c8a9f8d58337ed"
DESCRIPTION="A daemon to provide haptic feedback on events"
HOMEPAGE="https://source.puri.sm/Librem5/feedbackd"
SRC_URI="
https://source.puri.sm/Librem5/${PN}/-/archive/v${PV}/${PN}-v${PV}.tar.bz2
https://gitlab.gnome.org/guidog/gmobile/-/archive/${GMOBILE_COMMIT}.tar.bz2 -> gmobile-${GMOBILE_COMMIT}.tar.bz2
"
S="${WORKDIR}/${PN}-v${PV}"
LICENSE="LGPL-3"
KEYWORDS="~amd64 ~arm ~arm64 ~x86"
SLOT="0"
IUSE="+daemon gtk-doc +introspection man test +vala"
REQUIRED_USE="vala? ( introspection )"
RESTRICT="!test? ( test )"
DEPEND="
dev-libs/glib:2
daemon? (
dev-libs/json-glib
dev-libs/libgudev
media-libs/gsound
)
introspection? ( dev-libs/gobject-introspection )
"
RDEPEND="${DEPEND}
dev-libs/feedbackd-device-themes
"
BDEPEND="
dev-util/gdbus-codegen
gtk-doc? ( dev-util/gi-docgen )
man? ( dev-python/docutils )
vala? ( $(vala_depend) )
"
src_prepare() {
default
if use daemon; then
rmdir "${S}/subprojects/gmobile" || die
mv "${WORKDIR}/gmobile-${GMOBILE_COMMIT}" "${S}/subprojects/gmobile" || die
fi
use vala && vala_setup
sed -i 's/-G feedbackd/-G video/g' debian/feedbackd.udev || die
}
src_configure() {
local emesonargs=(
$(meson_feature introspection)
$(meson_use daemon)
$(meson_use gtk-doc gtk_doc)
$(meson_use man)
$(meson_use test tests)
$(meson_use vala vapi)
)
meson_src_configure
}
src_install() {
meson_src_install
udev_newrules debian/feedbackd.udev 90-feedbackd
if use gtk-doc; then
mkdir -p "${ED}"/usr/share/gtk-doc/html/ || die
mv "${ED}"/usr/share/doc/libfeedback-${SLOT} "${ED}"/usr/share/gtk-doc/html/ || die
fi
}
pkg_postinst() {
udev_reload
}
pkg_postrm() {
udev_reload
}