Removed
This commit is contained in:
parent
4e66d317f0
commit
89718e0de4
@ -1 +0,0 @@
|
||||
DIST evolution-3.54.2.tar.xz 13708916 BLAKE2B 9d5218d760bd17779b93a7a24356a70158aaeb8f245046738addba31c215e76c6f7ffb643d7d089e32861372899ced8cd2a3a8b57c02576f9389d560bd038e98 SHA512 7f9f0b48ea88c9c07c05bc7439f2c97ea5449c968823ef899d17451202849edfe69c4ca1bc8316980d5ea9e03fa395f727900c2bbe90c5639f09339f8ec79e00
|
||||
@ -1,161 +0,0 @@
|
||||
# Copyright 1999-2024 Gentoo Authors
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI=8
|
||||
|
||||
inherit cmake gnome2 readme.gentoo-r1
|
||||
|
||||
DESCRIPTION="Integrated mail, addressbook and calendaring functionality"
|
||||
HOMEPAGE="https://gitlab.gnome.org/GNOME/evolution/-/wikis/home https://gitlab.gnome.org/GNOME/evolution"
|
||||
|
||||
# Note: explicitly "|| ( LGPL-2 LGPL-3 )", not "LGPL-2+".
|
||||
LICENSE="|| ( LGPL-2 LGPL-3 ) CC-BY-SA-3.0 FDL-1.3+ OPENLDAP"
|
||||
SLOT="2.0"
|
||||
|
||||
KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~x86"
|
||||
|
||||
IUSE="archive +bogofilter geolocation gtk-doc highlight ldap libnotify selinux sound spamassassin spell ssl +weather ytnef"
|
||||
|
||||
# glade-3 support is for maintainers only per configure.ac
|
||||
# pst is not mature enough and changes API/ABI frequently
|
||||
# dconf explicitly needed for backup plugin
|
||||
# gnome-desktop support is optional with --enable-gnome-desktop
|
||||
# automagic libunity dep
|
||||
# >=gspell-1.8 to ensure it uses enchant:2 like webkit-gtk
|
||||
DEPEND="
|
||||
>=app-crypt/libsecret-0.5
|
||||
>=app-text/enchant-2.2.0:2
|
||||
>=dev-db/sqlite-3.7.17:3
|
||||
>=dev-libs/glib-2.66:2[dbus]
|
||||
>=dev-libs/libxml2-2.7.3:2
|
||||
>=gnome-base/gnome-desktop-2.91.3:3=
|
||||
>=gnome-base/gsettings-desktop-schemas-2.91.92
|
||||
>=gnome-extra/evolution-data-server-${PV}:=[gtk,sound?,weather?]
|
||||
>=net-libs/libsoup-3.0:3.0
|
||||
>=net-libs/webkit-gtk-2.38.0:4.1[spell?]
|
||||
>=x11-libs/cairo-1.9.15[glib]
|
||||
>=x11-libs/gdk-pixbuf-2.24:2
|
||||
>=x11-libs/gtk+-3.22:3
|
||||
>=x11-misc/shared-mime-info-0.22
|
||||
|
||||
app-text/cmark:=
|
||||
>=app-text/iso-codes-0.49
|
||||
>=app-accessibility/at-spi2-core-2.46.0:2
|
||||
|
||||
gnome-base/dconf
|
||||
|
||||
archive? ( >=app-arch/gnome-autoar-0.1.1[gtk] )
|
||||
bogofilter? ( mail-filter/bogofilter )
|
||||
geolocation? (
|
||||
>=media-libs/libchamplain-0.12.21:0.12[gtk]
|
||||
>=media-libs/clutter-1.0.0:1.0
|
||||
>=media-libs/clutter-gtk-0.90:1.0
|
||||
>=sci-geosciences/geocode-glib-3.26.3:2 )
|
||||
ldap? ( >=net-nds/openldap-2:= )
|
||||
libnotify? ( >=x11-libs/libnotify-0.7 )
|
||||
sound? (
|
||||
|| (
|
||||
media-libs/libcanberra-gtk3
|
||||
>=media-libs/libcanberra-0.25[gtk3(-)]
|
||||
)
|
||||
)
|
||||
spamassassin? ( mail-filter/spamassassin )
|
||||
spell? ( >=app-text/gspell-1.8:= )
|
||||
ssl? (
|
||||
>=dev-libs/nspr-4.6.1
|
||||
>=dev-libs/nss-3.11
|
||||
)
|
||||
weather? (
|
||||
>=dev-libs/libgweather-4.2.0:4=
|
||||
>=sci-geosciences/geocode-glib-3.26.3:2
|
||||
)
|
||||
ytnef? ( net-mail/ytnef )
|
||||
"
|
||||
RDEPEND="${DEPEND}
|
||||
highlight? ( app-text/highlight )
|
||||
selinux? ( sec-policy/selinux-evolution )
|
||||
"
|
||||
BDEPEND="
|
||||
app-text/docbook-xml-dtd:4.1.2
|
||||
dev-util/gdbus-codegen
|
||||
dev-util/glib-utils
|
||||
dev-util/itstool
|
||||
gtk-doc? ( dev-util/gtk-doc
|
||||
app-text/docbook-xml-dtd:4.3 )
|
||||
>=dev-util/intltool-0.40.0
|
||||
>=sys-devel/gettext-0.18.3
|
||||
virtual/pkgconfig
|
||||
"
|
||||
|
||||
DISABLE_AUTOFORMATTING="yes"
|
||||
DOC_CONTENTS="To change the default browser if you are not using GNOME, edit
|
||||
~/.local/share/applications/mimeapps.list so it includes the
|
||||
following content:
|
||||
|
||||
[Default Applications]
|
||||
x-scheme-handler/http=firefox.desktop
|
||||
x-scheme-handler/https=firefox.desktop
|
||||
|
||||
(replace firefox.desktop with the name of the appropriate .desktop
|
||||
file from /usr/share/applications if you use a different browser)."
|
||||
|
||||
# global scope PATCHES or DOCS array mustn't be used due to double default_src_prepare
|
||||
# call; if needed, set them after cmake_src_prepare call, if that works
|
||||
|
||||
src_prepare() {
|
||||
# libnotify is automagically detected, but a quick and easy way to
|
||||
# force-disable it is to delete the "yes it's there" variable from
|
||||
# CMakeLists.txt.
|
||||
use libnotify || sed '/HAVE_LIBNOTIFY/d' -i CMakeLists.txt || die
|
||||
|
||||
cmake_src_prepare
|
||||
gnome2_src_prepare
|
||||
}
|
||||
|
||||
src_configure() {
|
||||
# Use NSS/NSPR only if 'ssl' is enabled.
|
||||
local mycmakeargs=(
|
||||
-DSYSCONF_INSTALL_DIR="${EPREFIX}"/etc
|
||||
-DENABLE_SCHEMAS_COMPILE=OFF
|
||||
-DENABLE_GTK_DOC=$(usex gtk-doc)
|
||||
-DWITH_OPENLDAP=$(usex ldap)
|
||||
-DENABLE_SMIME=$(usex ssl)
|
||||
-DENABLE_GNOME_DESKTOP=ON
|
||||
-DWITH_ENCHANT_VERSION=2
|
||||
-DENABLE_CANBERRA=$(usex sound)
|
||||
-DENABLE_AUTOAR=$(usex archive)
|
||||
-DWITH_HELP=ON
|
||||
-DENABLE_YTNEF=OFF
|
||||
-DWITH_BOGOFILTER=$(usex bogofilter)
|
||||
-DWITH_SPAMASSASSIN=$(usex spamassassin)
|
||||
-DENABLE_GSPELL=$(usex spell)
|
||||
-DENABLE_TEXT_HIGHLIGHT=$(usex highlight)
|
||||
-DENABLE_WEATHER=$(usex weather)
|
||||
-DENABLE_CONTACT_MAPS=$(usex geolocation)
|
||||
-DENABLE_YTNEF=$(usex ytnef)
|
||||
-DENABLE_PST_IMPORT=OFF
|
||||
-DWITH_GLADE_CATALOG=OFF
|
||||
-DENABLE_MARKDOWN=ON
|
||||
)
|
||||
|
||||
cmake_src_configure
|
||||
}
|
||||
|
||||
src_compile() {
|
||||
cmake_src_compile
|
||||
}
|
||||
|
||||
src_test() {
|
||||
# -j1: https://gitlab.gnome.org/GNOME/evolution-data-server/-/issues/522
|
||||
cmake_src_test -j1
|
||||
}
|
||||
|
||||
src_install() {
|
||||
cmake_src_install
|
||||
readme.gentoo_create_doc
|
||||
}
|
||||
|
||||
pkg_postinst() {
|
||||
gnome2_pkg_postinst
|
||||
readme.gentoo_print_elog
|
||||
}
|
||||
@ -1 +0,0 @@
|
||||
DIST postfixadmin-3.3.13.tar.gz 1865708 BLAKE2B 0b5160e9996fa3b3580ee4f7dde128d6c4335c9929600158bb4e431f337b3a5ff6fe92cf8657102698b051b10c47ef134eb0a9d13d6675a3c701988bf4cefcb1 SHA512 bf7daaa089ee3adc4b557f1a7d0509d78979ef688fb725bab795f5c9d81e8774296245fde0cb184db51e9185cad381682c3ecc0bfadf852388b499a0a95cca64
|
||||
@ -1,47 +0,0 @@
|
||||
First Time Installation
|
||||
=======================
|
||||
PostfixAdmin can use either MySQL or PostgreSQL. It is up to you, or your
|
||||
database administrator, to provide a database and a user with full access to
|
||||
the database for use by PostfixAdmin.
|
||||
|
||||
If you are unfamiliar with MySQL or PostgreSQL, we have some good starting
|
||||
guides:
|
||||
|
||||
* http://www.gentoo.org/doc/en/mysql-howto.xml
|
||||
* https://wiki.gentoo.org/wiki/PostgreSQL
|
||||
|
||||
Once the database and user have been allocated, you will need to provide the
|
||||
details of this database and the associated user within the configuration file:
|
||||
|
||||
${MY_INSTALLDIR}/config.inc.php
|
||||
|
||||
In the same configuration file, check for other settings that are relevant to
|
||||
your setup. Once you're finished with your changes, make sure you set:
|
||||
|
||||
$CONF['configured'] = true;
|
||||
|
||||
To use Virtual Vacation, please read VIRTUAL_VACATION_INSTALL.
|
||||
|
||||
Finally you should be able to complete the installation of postfixadmin by
|
||||
pointing your browser at:
|
||||
|
||||
http://${VHOST_HOSTNAME}/${VHOST_APPDIR}/setup.php
|
||||
|
||||
Postfix Admin contains 3 views of administration:
|
||||
1. Site Admin view, located at http://${VHOST_HOSTNAME}/${VHOST_APPDIR}/admin/.
|
||||
2. Domain Admin view, located at http://${VHOST_HOSTNAME}/${VHOST_APPDIR}/.
|
||||
3. User Admin View, located at http://${VHOST_HOSTNAME}/${VHOST_APPDIR}/users/.
|
||||
|
||||
In order to do the initial configuration you have to go to the Site Admin view.
|
||||
|
||||
Upgrading
|
||||
=========
|
||||
When updating from older version of PostfixAdmin, make sure you backup your
|
||||
database before you run the update script on your database.
|
||||
|
||||
* mysqldump -a -u root -p > /tmp/postfixadmin-backup.sql
|
||||
* pg_dump -U postgres -d postgres -C -f pa-db-backup.sql postfixadmin_db
|
||||
|
||||
For update from version 1.5.x of PostfixAdmin:
|
||||
1. Please read the DOCUMENTS/UPGRADE.TXT
|
||||
2. Run: http://${VHOST_HOSTNAME}/${VHOST_APPDIR}/setup.php
|
||||
@ -1,104 +0,0 @@
|
||||
# Copyright 1999-2023 Gentoo Authors
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI=8
|
||||
|
||||
inherit webapp
|
||||
|
||||
DESCRIPTION="Web Based Management tool for Postfix style virtual domains and users"
|
||||
HOMEPAGE="http://postfixadmin.sourceforge.net"
|
||||
SRC_URI="https://github.com/postfixadmin/postfixadmin/archive/${P}.tar.gz"
|
||||
S="${WORKDIR}/${PN}-${P}"
|
||||
|
||||
LICENSE="GPL-2"
|
||||
KEYWORDS="~amd64 ~ppc ~x86 ~arm ~arm64"
|
||||
IUSE="+mysql postgres +vacation"
|
||||
REQUIRED_USE="|| ( mysql postgres )"
|
||||
|
||||
DEPEND="
|
||||
dev-lang/php:*[unicode,imap,postgres?]
|
||||
vacation? (
|
||||
acct-group/vacation
|
||||
acct-user/vacation
|
||||
dev-perl/DBI
|
||||
dev-perl/Email-Sender
|
||||
dev-perl/Email-Valid
|
||||
dev-perl/Log-Dispatch
|
||||
dev-perl/Log-Log4perl
|
||||
dev-perl/MIME-Charset
|
||||
dev-perl/MIME-EncWords
|
||||
mysql? ( dev-perl/DBD-mysql )
|
||||
postgres? ( dev-perl/DBD-Pg )
|
||||
)
|
||||
"
|
||||
|
||||
RDEPEND="
|
||||
${DEPEND}
|
||||
virtual/httpd-php
|
||||
mysql? ( || ( dev-lang/php[mysqli] dev-lang/php[mysql] ) )
|
||||
"
|
||||
|
||||
need_httpd_cgi
|
||||
|
||||
pkg_setup() {
|
||||
webapp_pkg_setup
|
||||
}
|
||||
|
||||
src_install() {
|
||||
webapp_src_preinst
|
||||
|
||||
if use vacation; then
|
||||
insinto /var/spool/vacation
|
||||
newins VIRTUAL_VACATION/vacation.pl vacation.pl-${SLOT}
|
||||
fperms 755 /var/spool/vacation/vacation.pl-${SLOT}
|
||||
dodoc VIRTUAL_VACATION/FILTER_README
|
||||
newdoc VIRTUAL_VACATION/INSTALL.md VIRTUAL_VACATION_INSTALL.md
|
||||
rm -r VIRTUAL_VACATION/{vacation.pl,INSTALL.md,tests,FILTER_README} || die
|
||||
fi
|
||||
|
||||
dodoc -r ADDITIONS
|
||||
|
||||
local docs="DOCUMENTS/*.txt INSTALL.TXT CHANGELOG.TXT"
|
||||
dodoc ${docs}
|
||||
|
||||
rm -rf ${docs} DOCUMENTS/ GPL-LICENSE.TXT LICENSE.TXT debian/ tests/ ADDITIONS/
|
||||
|
||||
insinto "${MY_HTDOCSDIR}"
|
||||
doins -r .
|
||||
|
||||
webapp_configfile "${MY_HTDOCSDIR}"/config.inc.php
|
||||
|
||||
webapp_postinst_txt en "${FILESDIR}"/postinstall-en-2.3.txt
|
||||
webapp_src_install
|
||||
}
|
||||
|
||||
pkg_postinst() {
|
||||
webapp_pkg_postinst
|
||||
|
||||
einfo "Please note that if upgrading from version prior to 3.3.0,"
|
||||
einfo "existing setup_password will no longer work and you will"
|
||||
einfo "need to generate new one. See instructions in setup.php."
|
||||
|
||||
if use vacation; then
|
||||
# portage does not update owners of directories (feature :)
|
||||
chown vacation:vacation "${ROOT}"/var/spool/vacation/
|
||||
einfo
|
||||
einfo "/var/spool/vacation/vacation.pl symlink was updated to:"
|
||||
einfo "/var/spool/vacation/vacation.pl-${SLOT}"
|
||||
ln -sf "${ROOT}"/var/spool/vacation/vacation.pl{-${SLOT},} || die
|
||||
fi
|
||||
}
|
||||
|
||||
pkg_postrm() {
|
||||
# Make sure we don't leave broken vacation.pl symlink
|
||||
find -L "${ROOT}"/var/spool/vacation/ -type l -delete
|
||||
local shopt_save=$(shopt -p nullglob)
|
||||
shopt -s nullglob
|
||||
local vacation=( "${ROOT}"/var/spool/vacation/vacation.pl-* )
|
||||
${shopt_save}
|
||||
if [[ ! -e "${ROOT}"/var/spool/vacation/vacation.pl && -n ${vacation[@]} ]]; then
|
||||
ln -s "${vacation[-1]}" "${ROOT}"/var/spool/vacation/vacation.pl || die
|
||||
ewarn "/var/spool/vacation/vacation.pl was updated to point on most"
|
||||
ewarn "recent verion, but please, do your own checks"
|
||||
fi
|
||||
}
|
||||
Loading…
x
Reference in New Issue
Block a user