Added tracker

app-misc/tracker/Manifest

@@ -0,0 +1 @@
+DIST tracker-3.1.1.tar.xz 1434784 BLAKE2B fa73420736e82bc7a43ef9dd9dce9096e50a22aca3f83737a0c77802460fc307630403bb836a799ff2d03a838cd1e71fbb4a17a54fa0a7c823e122800530e050 SHA512 87e6cc6dbfb34cc17bef42defefc51fc9d9586bffebf7a282a89ec3b294e911c504ea862bb05e5a269e438a83fbeb8938670eb32fa11d0d09ba805e0b02e6dcd

app-misc/tracker/tracker-3.1.1.ebuild

@@ -0,0 +1,102 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{6,7,8} )
+VALA_MIN_API_VERSION="0.40"
+
+inherit bash-completion-r1 gnome.org gnome2-utils linux-info meson python-any-r1 systemd vala xdg
+
+DESCRIPTION="A tagging metadata database, search tool and indexer"
+HOMEPAGE="https://wiki.gnome.org/Projects/Tracker"
+
+LICENSE="GPL-2+ LGPL-2.1+"
+SLOT="3/3.0"
+IUSE="gtk-doc +miners networkmanager stemmer"
+
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+#RESTRICT="!test? ( test )"
+
+PV_SERIES=$(ver_cut 1-2)
+
+# In 2.2.0 util-linux should only be necessary if glib is older than 2.52 at compile-time
+# But build still needs it - https://gitlab.gnome.org/GNOME/tracker/issues/131
+# FIXME: need ln -s /usr/share/asciidoc to /etc/asciidoc to compile
+RDEPEND="
+	>=dev-libs/glib-2.46:2
+	>=sys-apps/dbus-1.3.2
+	>=dev-libs/gobject-introspection-1.54:=
+	>=dev-libs/icu-4.8.1.2:=
+	>=dev-libs/json-glib-1.0
+	>=net-libs/libsoup-2.40.1:2.4
+	>=dev-libs/libxml2-2.7
+	>=dev-db/sqlite-3.20.0
+	networkmanager? ( >=net-misc/networkmanager-0.8 )
+	stemmer? ( dev-libs/snowball-stemmer )
+	sys-apps/util-linux
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	dev-util/glib-utils
+	$(vala_depend)
+	gtk-doc? ( >=dev-util/gtk-doc-1.8
+		app-text/docbook-xml-dtd:4.1.2
+		app-text/docbook-xml-dtd:4.5 )
+	>=sys-devel/gettext-0.19.8
+	>=app-text/asciidoc-9.1.0
+	virtual/pkgconfig
+	${PYTHON_DEPS}
+"
+PDEPEND="miners? ( >=app-misc/tracker-miners-${PV_SERIES} )"
+
+function inotify_enabled() {
+	if linux_config_exists; then
+		if ! linux_chkconfig_present INOTIFY_USER; then
+			ewarn "You should enable the INOTIFY support in your kernel."
+			ewarn "Check the 'Inotify support for userland' under the 'File systems'"
+			ewarn "option. It is marked as CONFIG_INOTIFY_USER in the config"
+			die 'missing CONFIG_INOTIFY'
+		fi
+	else
+		einfo "Could not check for INOTIFY support in your kernel."
+	fi
+}
+
+pkg_setup() {
+	linux-info_pkg_setup
+	inotify_enabled
+
+	python-any-r1_pkg_setup
+}
+
+src_prepare() {
+	xdg_src_prepare
+	vala_src_prepare
+}
+
+src_configure() {
+	local emesonargs=(
+		-Dfts=true
+		-Dfunctional_tests=false # many fail in 2.2; retry with 2.3
+		#$(meson_use test functional_tests)
+		-Dman=true
+		$(meson_feature networkmanager network_manager)
+		$(meson_feature stemmer)
+		-Dunicode_support=icu
+	)
+	meson_src_configure
+}
+
+src_test() {
+	dbus-run-session meson test -C "${BUILD_DIR}" || die 'tests failed'
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}