Added

gnome-extra/gnome-power-manager/Manifest

@@ -0,0 +1 @@
+DIST gnome-power-manager-3.32.0.tar.xz 379136 BLAKE2B 3f9b385c37fcf1de3741781627d275057f67d489ed4b372f6f68495a707d9e67b78be9f186922a99a606a80008addd570943800ddb2ddd17d2071161b7276c49 SHA512 0ea11085dd015e30c1bdc6913000b63eabf7df76720f2d51d63b075f3b7bd2a610aaa484c53a4092d78d3c484ed8c4e81ec66603bdc6c132b0316113ec6a24a0

gnome-extra/gnome-power-manager/gnome-power-manager-3.32.0.ebuild

@@ -0,0 +1,56 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit gnome.org gnome2-utils meson virtualx xdg
+
+DESCRIPTION="GNOME power statistics"
+HOMEPAGE="https://gitlab.gnome.org/GNOME/gnome-power-manager"
+
+LICENSE="GPL-2+"
+SLOT="0"
+IUSE="test"
+RESTRICT="!test? ( test )"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+
+COMMON_DEPEND="
+	>=dev-libs/glib-2.45.8:2
+	>=x11-libs/gtk+-3.3.8:3
+	>=x11-libs/cairo-1
+	>=sys-power/upower-0.99.8:=
+"
+RDEPEND="${COMMON_DEPEND}
+	x11-themes/adwaita-icon-theme
+"
+DEPEND="${COMMON_DEPEND}
+	app-text/docbook-sgml-dtd:4.1
+	app-text/docbook-sgml-utils
+	>=sys-devel/gettext-0.19.7
+	x11-base/xorg-proto
+	virtual/pkgconfig
+	test? ( sys-apps/dbus )
+"
+
+# docbook-sgml-utils and docbook-sgml-dtd-4.1 used for creating man pages
+# (files under ${S}/man).
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use test enable-tests)
+	)
+	meson_src_configure
+}
+
+src_test() {
+	virtx meson_src_test
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}